计算得出的 DAX 查找值 table

Question

我需要在一个 table 中添加一列，其中包含一组另一个 table 的最小值。

我有一个 Table A 具有唯一 ID。

在这个 table 中，我需要添加一列 min_value，其中包含另一个 table Table B 中每个 ID 的最小值：

我知道我可以在我的 Table B 上使用 SUMMARIZE() 来创建一个具有每个 ID 最小值的计算 table，保存这个 Table C 然后在我的 Table A 和 Table C 之间使用 LOOKUPVALUE() 来获取我在 Table A 中需要的列。但是我不想保存这个Table C，因为它不会被再次使用，而且我没有找到一种方法可以在我的LOOKUPVALUE()中直接使用我的SUMMARIZE()的结果而不保存计算出的 table.

Answer 1

请尝试在此处提供 table 格式的示例数据。

根据这两个 table 之间的关系以及您是否需要计算列或度量，有很多方法可以实现您想要的。

Calculated Column - with relationship between 'Table A'[ID] and 'Table B'[ID]

ALLEXCEPT = --can be utilized as a measure too
CALCULATE ( MIN ( 'Table B'[Value] ), ALLEXCEPT ( 'Table A', 'Table A'[ID] ) )

RELATEDTABLE =
    MINX ( RELATEDTABLE ( 'Table B' ), 'Table B'[Value] )
    
IN =
CALCULATE (
    MINX ( 'Table B', 'Table B'[Value] ),
    'Table A'[ID] IN VALUES ( 'Table B'[ID] )
)

Calculated Column - with no relationship between 'Table A' and 'Table B'

TREATAS =
CALCULATE (
    CALCULATE (
        MINX ( 'Table B', 'Table B'[Value] ),
        TREATAS ( VALUES ( 'Table A'[ID] ), 'Table B'[ID] )
    )
)

Measure - with relationship between 'Table A'[ID] and 'Table B'[ID]

_in =
CALCULATE (
    MIN ( 'Table B'[Value] ),
    'Table A'[ID] IN VALUES ( 'Table B'[ID] )
)

Measure - with no relationship between 'Table A' and 'Table B'

_treatas =
CALCULATE (
    MIN ( 'Table B'[Value] ),
    TREATAS ( VALUES ( 'Table A'[ID] ), 'Table B'[id] )
)

计算得出的 DAX 查找值 table

DAX lookupvalue from calculated table

dax

powerbi