转换静态数组以打开不同元素类型的数组

Question

（我已经在 CodeReview 上问过这个问题，因为它离题而被关闭。希望它在这里是题外话。）

我有一个派生类型的静态数组（如以下示例代码中的 LabelsA: array[0..3] of TLabel;）和一个接受基本类型的开放数组的例程（如 procedure DoSomethingWithControls(const AControls: array of TControl);），我想要使用这些静态数组调用 DoSomethingWithControls。请看我的样本：

procedure DoSomethingWithControls(const AControls: array of TControl);
var
  i: Integer;
begin
  for i := Low(AControls) to High(AControls) do
    Writeln(AControls[i].Name);
end;

procedure Test;
var
  LabelsA: array[0..3] of TLabel;
  LabelsB: array[0..1] of TLabel;

  procedure Variant1;
  type
    TArray1 = array[Low(LabelsA)..High(LabelsA)] of TControl;
    TArray2 = array[Low(LabelsB)..High(LabelsB)] of TControl;
  begin
    DoSomethingWithControls(TArray1(LabelsA));
    DoSomethingWithControls(TArray2(LabelsB));
  end;

  procedure Variant2;
  type
    TControlArray = array[0..Pred(MaxInt div SizeOf(TControl))] of TControl;
    PControlArray = ^TControlArray;
  begin
    DoSomethingWithControls(Slice(PControlArray(@LabelsA)^, Length(LabelsA)));
    DoSomethingWithControls(Slice(PControlArray(@LabelsB)^, Length(LabelsB)));
  end;

  procedure Variant3;
  var
    ControlsA: array[Low(LabelsA)..High(LabelsA)] of TControl absolute LabelsA;
    ControlsB: array[Low(LabelsB)..High(LabelsB)] of TControl absolute LabelsB;
  begin
    DoSomethingWithControls(ControlsA);
    DoSomethingWithControls(ControlsB);
  end;

begin
  Variant1;
  Variant2;
  Variant3;
end;

有一些可能的调用变体 DoSomethingWithControls:

变体 1 非常简单，但需要 "adapter" 类型，例如 TArray1 对于每个大小的 TLabel 数组。我希望它更灵活。
变体 2 更灵活和统一，但丑陋且容易出错。
变体 3（由 ) 类似于变体 1 - 它不需要显式转换，但变体 1 提供了如果你搞砸了一些东西（例如复制粘贴时数组边界错误）。

关于如何在没有这些缺点的情况下（不更改数组的元素类型）制定这些调用有什么想法吗？它应该适用于 D2007 和 XE6。

Answer 1

也不是很漂亮，但你可以像这样欺骗编译器：

procedure Variant3;
var
  ControlsA: array[Low(LabelsA)..High(LabelsA)] of TControl absolute LabelsA;
begin
  DoSomethingWithControls(ControlsA);
end;

Answer 2

这些造型都比较丑。它们都可以工作，但使用它们会让您感到肮脏。使用辅助函数是完全合理的：

type
  TControlArray = array of TControl;

function ControlArrayFromLabelArray(const Items: array of TLabel): TControlArray;
var 
  i: Integer;
begin
  SetLength(Result, Length(Items));
  for i := 0 to high(Items) do
    Result[i] := Items[i];
end;

然后你这样调用你的函数：

DoSomethingWithControls(ControlArrayFromLabelArray(...));

当然，如果您可以使用泛型，这会更简洁。

Answer 3

由于动态数组可以作为开放数组传递到方法中，因此可以选择将静态数组转换为动态数组。

如果您不介意复制数组的开销，请考虑以下事项：

编写一个函数将一个开放的标签数组转换成一个动态的 TControlArray 数组。

type
  TControlArray = array of TControl;

{$IFOPT R+} {$DEFINE R_ON} {$R-} {$ENDIF}
function MakeControlArray(const ALabels: array of TLabel): TControlArray;
begin
  SetLength(Result, Length(ALabels));
  Move(ALabels[0], Result[0], Length(ALabels) * SizeOf(TObject));
end;
{$IFDEF R_ON} {$R+} {$UNDEF R_ON} {$ENDIF}

现在Variant4可以写成：

procedure Variant4;
begin
  DoSomethingWithControls(MakeControlArray(LabelsA));
  DoSomethingWithControls(MakeControlArray(LabelsB));
end;

测试用例：

procedure TAdHocTests.TestLabelsToControls;
const
  LLabelsA: array[0..3] of TLabel = (Pointer(0),Pointer(1),Pointer(2),Pointer(3));
var
  LLoopI: Integer;
  LLabelsB: array[0..9] of TLabel;
  LEmptyArray: TLabelArray;
begin
  for LLoopI := Low(LLabelsB) to High(LLabelsB) do
  begin
    LLabelsB[LLoopI] := Pointer(LLoopI);
  end;

  DoSomethingWithControls(MakeControlArray(LLabelsA), Length(LLabelsA));
  DoSomethingWithControls(MakeControlArray(LLabelsB), Length(LLabelsB));
  DoSomethingWithControls(MakeControlArray([]), 0);
  DoSomethingWithControls(MakeControlArray(LEmptyArray), 0);
end;

procedure TAdHocTests.DoSomethingWithControls(
    const AControls: array of TControl;
    AExpectedLength: Integer);
var
  LLoopI: Integer;
begin
  CheckEquals(AExpectedLength, Length(AControls), 'Length incorrect');
  for LLoopI := Low(AControls) to High(AControls) do
  begin
    CheckEquals(LLoopI, Integer(AControls[LLoopI]));
  end;
end;

Answer 4

声明一个重载过程：

procedure DoSomethingWithControls(const AControls: array of TControl); overload;
var
  i: Integer;
begin
  for i := 0 to High(AControls) do
    if Assigned(AControls[i]) then
       Writeln(AControls[i].Name)
    else
      WriteLn('Control item: ',i);
end;

procedure DoSomethingWithControls(const ALabels: array of TLabel); overload;
type
  TControlArray = array[0..Pred(MaxInt div SizeOf(TControl))] of TControl;
  PControlArray = ^TControlArray;
begin
  DoSomethingWithControls(Slice(PControlArray(@ALabels)^, Length(ALabels)));
end;

这是针对您的变体 2 的通用解决方案。所有情况一次申报，不易出错。

Answer 5

下面的例子是基于内部如何实现开放数组参数的。但是，它不适用于 "typed @ operator"。

  procedure Variant4;
  type
    TCallProc = procedure (AControls: Pointer; HighBound: Integer);
  var
    CallProc: TCallProc;
  begin
    CallProc := @DoSomethingWithControls;

    CallProc(@LabelsA, Length(LabelsA) - 1);
    CallProc(@LabelsB, Length(LabelsB) - 1);
  end;

为 HighBound 传递 High(Labels) 可能更好，只要所有静态数组都基于 0。

转换静态数组以打开不同元素类型的数组

Cast static array to open array of different element type

arrays

delphi

casting

open-array-parameters