在 Haskell 中定义自定义运算符的关联性

Question

我正在研究自定义运算符 infix、infixl 和 infixr。现在我很困惑。

我已经为列表乘法编写了一个自定义运算符，并且认为将其声明为一个没有方向关联性的简单中缀运算符会自动提供两种情况，nr * list 和 list * number，因为它们可以随意互换。

import Prelude hiding ((*))

infix 6 *

(*) :: Int -> [a] -> [a]
n * l = if n < 0 then [] 
                 else l ++ (n - 1) * l

现在，3 * [1, 2, 3] returns [1, 2, 3, 1, 2, 3, 1, 2, 3] 符合预期，但是 [1, 2, 3] * 3 抛出错误，因为我从未明确定义 list * nr.

我的问题：infix 的独特功能是什么？为什么不总是使用 infixl 或 infixr，因为它们应该没什么区别？

我理解“无方向结合性”/infix 是“可交换”的同义词：

a + b + c没有方向结合律，是可交换的，可以写成(a + b) + c、a + (b + c)、b + a + c、(b + a) + c等。 ..

对于我的示例 2 * [1, 2] * 1 与 1 * (2 * [1, 2]) 以及所有其他组合相同，所以我真的不明白，为什么没有对可交换运算符声明的隐式重塑，即使有不同的键入的操作数。

Answer 1

固定性声明只影响解析，不影响运算符的定义。

如果使用infixl，则a * b * c被解析为(a * b) * c。

如果你使用infixr，那么a * b * c被解析为a * (b * c)。

如果你用infix，那么你就是说a * b * c无法解析；您必须使用括号来指定您的意思是 (a * b) * c 还是 a * (b * c)。比较

Prelude> infix 6 ***; (***) = (+)
Prelude> 1 *** 2 *** 3

<interactive>:8:1: error:
    Precedence parsing error
        cannot mix ‘***’ [infix 6] and ‘***’ [infix 6] in the same infix expression
Prelude> infixl 6 ***; (***) = (+)
Prelude> 1 *** 2 *** 3
6

在你的情况下，* 不是完全关联的，因为类型不对齐。它可以是右结合的，因为 3 * (6 * []) 类型检查但不是左结合的，因为 (3 * 6) * [] 没有。使用 infix，您不允许 3 * 6 * []。如果您使用 infixr，那么您可以这样写，解析器会将其视为 3 * (6 * [])。

制作这样的运算符 可交换 很棘手，因为在类型级别它们是两个不同的运算符。这很容易定义：

-- Ignoring the fact that both of these operators are already
-- used by the Applicative class for different purposes.

(*>) :: Int -> [a] -> [a]
0 *> l = []
n *> l = l ++ (n-1) * l

(<*) :: [a] -> Int -> [a]
(<*) = flip (*>)

让 * 同时作为 Int -> [a] -> [a] 和 [a] -> Int -> [a] 工作是很棘手的，如果不是不可能的话。（也许涉及多参数类型族？

-- Compiles, but does not run. Not sure why...
{-# LANGUAGE TypeFamilies, MultiParamTypeClasses, FlexibleContexts #-}

class Multiplable x y where
  type Result x y
  (***) :: x -> y -> Result x y

instance Multiplable Int [a] where
   type Result Int [a] = [a]
   0 *** l = []
   n *** l = l ++ ((n - 1) *** l)

instance Multiplable [a] Int where
  type Result [a] Int = [a]
  l *** 0 = []
  l *** n = l ++ (l *** (n - 1))

)

你对结合律和交换律的理解是错误的。 “非结合”不是“可交换”的同义词。事实上，这两个属性是正交的：一个给定的运算符可以是两者，或者两者都不是，或者只是两者之一。

整数加法是结合和交换的。
整数减法既不结合也不交换。
矩阵乘法是结合的，但不是交换的。（BA 可以不同于 AB 甚至完全未定义。）

NAND 运算（逻辑与的否定）是可交换的，但不是结合的：

(True NAND True) NAND False == False NAND False == True
True NAND (True NAND False) == True NAND True == False

在 Haskell 中定义自定义运算符的关联性

Defining the associativity of a custom operator in Haskell

haskell

operators

infix-operator