如何在 Perl 的 ImageMagick API PerlMagick 中将 svg 转换为 png？

Question

如何将 svg 图像转换为 png，将其保存到文件并收集有关它的基本信息？

#!/usr/bin/perl 
use strict;
use warnings;
use Image::Magick;

my $svg = <<'SVG';
<?xml version="1.0" encoding="utf-8" ?>
<svg xmlns="http://www.w3.org/2000/svg" version="1.1">
  <rect fill="white" height="87" rx="10" ry="10" stroke="black" stroke-width="1" width="56" x="0" y="0"/>
</svg>
SVG

my $im = Image::Magick->new();
$im->Read(blob => $svg) or die "Could not read: $!";

$im->Write(filename => 'test.png') or die "Cannot write: $!";
my $width = $im->Get('height') || '(undef)';
my $height = $im->Get('width') || '(undef)';
my $size = $im->Get('filesize') || '(undef)';

print "$height x $width, $size bytes\n";

当我运行这个时，我得到：

(undef) x (undef), (undef) bytes

没有错误，没有 test.png，图像尺寸未定义。

如何在 PerlMagick 中将 svg 图像转换为 png？

至于这是否重复：大多数其他问题、博客文章和教程都使用命令行 ImageMagick convert 工具。我想避免这种情况。我目前调用 Inkscape 进行转换，但分析器将这些调用显示为我的代码库中的热点之一。我正在处理约 320 个 svg 文件，转换它们需要约 15 分钟。我希望通过库可以获得更好的性能，因为我不需要创建新进程和写入临时文件。我也在调查 Inkscape shell.

Answer 1

您必须指定 SVG 图像的宽度和高度。以下对我有用：

use strict;
use warnings;
use Image::Magick;

my $svg = <<'SVG';
<?xml version="1.0" encoding="utf-8" ?>
<svg xmlns="http://www.w3.org/2000/svg" width="300" height="200" version="1.1">
  <rect fill="white" height="87" rx="10" ry="10" stroke="black" stroke-width="1" width="56" x="0" y="0"/>
</svg>
SVG
my $im = Image::Magick->new(magick => 'svg');
my $status;
$status = $im->BlobToImage($svg) and warn $status;
$status = $im->Write(filename => 'test.png') and warn $status;
my $width = $im->Get('height') || '(undef)';
my $height = $im->Get('width') || '(undef)';
my $size = $im->Get('filesize') || '(undef)';
print "$height x $width, $size bytes\n";

输出:

300 x 200, 1379 bytes

如何在 Perl 的 ImageMagick API PerlMagick 中将 svg 转换为 png？

How do I convert a svg to png in Perl's ImageMagick API PerlMagick?

perl

imagemagick

perlmagick