Copying/pasting 在 D2009+ 中使用 TMemoryStream 和 TClipboard

Question

我有一个方法可以读取 TStringGrid 的一行单元格中的数据，并将其复制到剪贴板。我有相应的方法将剪贴板中的数据粘贴到 TStringGrid.

中的空行中

这些方法是为 D7 编写的，但在迁移到 XE2 后就失效了。

procedure TfrmBaseRamEditor.CopyLine(Sender: TObject; StrGridTemp: TStringGrid;
                                     Row, Column: Integer);
var
  Stream: TMemoryStream;
  MemHandle: THandle;
  MemBlock: Pointer;
  i, Len: Integer;
  RowStr: String;
begin
  Stream := nil;
  try
    Stream := TMemoryStream.Create;

    // The intermediate format to write to the stream.
    // Separate each item by horizontal tab character.
    RowStr := '';
    for i := 0 to (StrGridTemp.ColCount - 1) do
      RowStr := RowStr + StrGridTemp.Cells[i, Row] + #9;
    // Write all elements in a string.
    Len := Length(RowStr);
    Stream.Write(Len, SizeOf(Len));
    Stream.Write(PChar(RowStr)^, Length(RowStr));
    // Request Memory for the clipboard.
    MemHandle := GlobalAlloc(GMEM_DDESHARE, Stream.SIZE);
    MemBlock := GlobalLock(MemHandle);
    try
      // Copy the contents of the stream into memory.
      Stream.Seek(0, soFromBeginning);
      Stream.Read(MemBlock^, Stream.SIZE);
    finally
      GlobalUnlock(MemHandle);
    end;
    // Pass the memory to the clipboard in the correct format.
    Clipboard.Open;
    Clipboard.SetAsHandle(TClipboardFormat, MemHandle);
    Clipboard.Close;
  finally
    Stream.Free;
  end;
end;

procedure TfrmBaseRamEditor.PasteLine(Sender: TObject; StrGridTemp: TStringGrid;
                                      Row, Column: Integer);
var
  Stream: TMemoryStream;
  MemHandle: THandle;
  MemBlock: Pointer;
  ASize, Len, i: Integer;
  TempStr: String;
begin
  Clipboard.Open;
  try
    // If something is in the clipboard in the correct format.
    if Clipboard.HasFormat(TClipboardFormat) then
    begin
      MemHandle := Clipboard.GetAsHandle(TClipboardFormat);
      if MemHandle <> 0 then
      begin
        // Detect size (number of bytes).
        ASize := GlobalSize(MemHandle);
        Stream := nil;
        try
          Stream := TMemoryStream.Create;
          // Lock the contents of the clipboard.
          MemBlock := GlobalLock(MemHandle);
          try
            // Copy the data into the stream.
            Stream.Write(MemBlock^, ASize);
          finally
            GlobalUnlock(MemHandle);
          end;
          Stream.Seek(0, soFromBeginning);
          Stream.Read(Len, SizeOf(Len));
          SetLength(TempStr, Len);
          Stream.Read(PChar(TempStr)^, Stream.SIZE);
          for i := 0 to StrGridTemp.RowCount do
            StrGridTemp.Cells[i, Row] := NextStr(TempStr, #9);
        finally
          Stream.Free;
        end;
      end;
    end;
  finally
    Clipboard.Close;
  end;
end;

当我复制包含一些值的行，然后将其粘贴到一个空行时，问题就出现了。第一个单元格粘贴正确，但第二个单元格包含乱码（并且从第 3 列开始没有粘贴任何内容）。我知道为什么从第 3 列开始没有粘贴任何内容：因为分隔列的 "horizontal tab" 字符与单元格内容一起损坏。

我已经仔细阅读了 Marco Cantu 的“Delphi and Unicode”，但一直无法弄清楚哪里出了问题。

Answer 1

Char 是 WideChar 的别名。所以在 CopyLine

Stream.Write(PChar(RowStr)^, Length(RowStr));

只写了一半的字符串。应该是

Stream.Write(PChar(RowStr)^, Length(RowStr)*SizeOf(Char));

在 PasteLine 中，我发现这一行很奇怪：

Stream.Read(PChar(TempStr)^, Stream.SIZE);

由于您已经使用了一些字符串，因此您正试图读到最后。我会这样写：

Stream.Read(PChar(TempStr)^, Len*SizeOf(Char));

请注意，如果您使用与 ANSI 程序相同的自定义剪贴板格式标识符，那么如果您从一个程序复制并粘贴到另一个程序，就会出现编码不匹配的情况。为新的 Unicode 格式在不同的剪贴板格式下注册可能是明智的。

其他一些评论：

Stream := nil;
try
  Stream := TMemoryStream.Create;
  ...
finally
  Stream.Free;
end;

应该写成：

Stream := TMemoryStream.Create;
try
  ...
finally
  Stream.Free;
end;

如果构造函数抛出异常，则不会进入try块。

你真的不需要写出字符串长度。您可以在阅读时依靠流大小来了解字符串的长度。

在 CopyLine 中，剪贴板 Open 和 Close 调用应由 try/finally 块保护。

Copying/pasting 在 D2009+ 中使用 TMemoryStream 和 TClipboard

Copying/pasting with TMemoryStream and TClipboard in D2009+

migration

delphi

clipboard

delphi-xe2