删除 xsl-fo 中的 table 个单元格

Question

我遇到这个问题，我需要删除 table 个空的单元格。但他们总是留下一个小缺口。

如果用户填写每一个选项，table是正常的。如果用户只填写了一些字段，那么 table 会生成这条深色水平线。我怀疑是空单元格聚在一起。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
<xsl:output version="1.0" encoding="UTF-8" indent="yes" omit-xml-declaration="yes" media-type="text/html" />

<xsl:template match="fwcF17Part35Page">
  <xsl:apply-templates select="part35Details"/>
</xsl:template>

<xsl:template match="part35Details">
<fo:block keep-together.within-page="always">
   <fo:block padding="5pt"/>
  <fo:block font-size="16pt" text-align="left">
    Upload Documents - test
  </fo:block>
  <fo:block>
    <fo:leader leader-pattern="rule" leader-length="100%" rule-style="solid" rule-thickness="2pt"/>
  </fo:block>
  <fo:block padding="8pt"/>
  <fo:block background-color="#ebe8e8" font-size="10pt" font-weight="bold">
    Document(s)
  </fo:block>
<fo:block padding="4px" font-size="8pt" font-weight="normal" text-align="center">
  <fo:table>
    <fo:table-column column-width="50%" />
    <fo:table-column column-width="50%" />
    <fo:table-header>
      <fo:table-row>
        <fo:table-cell border-style="solid" padding="2pt">
          <fo:block font-weight="bold">Document Name</fo:block>
        </fo:table-cell>
        <fo:table-cell border-style="solid" padding="2pt">
          <fo:block font-weight="bold">Document Type</fo:block>
        </fo:table-cell>
      </fo:table-row>
    </fo:table-header>
    <fo:table-body>
      <xsl:for-each select="/root/pages/page_12/sections/fwcF17DocumentUpload/data">
        <fo:table-row>
            <xsl:choose>
              <xsl:when test="size > 0">
                <fo:table-cell border-style="solid" padding="2pt">
                  <fo:block>
                    <xsl:value-of select="name" />
                  </fo:block>
                </fo:table-cell>
              </xsl:when>
              <xsl:otherwise>
                <fo:table-cell>
                  <fo:block>
                  </fo:block>
                </fo:table-cell>
              </xsl:otherwise>
            </xsl:choose>
            <xsl:choose>
              <xsl:when test="size > 0">
                <fo:table-cell border-style="solid" padding="2pt">
                  <fo:block>
                    <xsl:value-of select="documentType" />
                  </fo:block>
                </fo:table-cell>
              </xsl:when>
              <xsl:otherwise>
                <fo:table-cell>
                  <fo:block>
                  </fo:block>
                </fo:table-cell>
              </xsl:otherwise>
            </xsl:choose>
        </fo:table-row>
      </xsl:for-each>
    </fo:table-body>
  </fo:table>
</fo:block>
</fo:block>
</xsl:template>
</xsl:stylesheet>

我试过输入：

<fo:table-cell visilibity="hidden">
<fo:table-cell display="none">
<fo:table-cell height="0px">

有空单元格时输出错误：

没有空单元格时的正确输出：

Answer 1

仅当您的数据满足过滤器 size > 0

时才创建 fo:table-row

您可以通过为您的 for-each 添加一个谓词来做到这一点。此外，您可以在匹配中使用相同的谓词，确保不会构造无效的 fo:table。然后 xslt 将如下所示：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
  <xsl:output version="1.0" encoding="UTF-8" indent="yes" omit-xml-declaration="yes" media-type="text/html" />
  
  <xsl:template match="fwcF17Part35Page">
    <xsl:apply-templates select="part35Details"/>
  </xsl:template>
  
  <xsl:template match="part35Details[/root/pages/page_12/sections/fwcF17DocumentUpload/data[size &gt; 0]]">
    <fo:block keep-together.within-page="always">
      <fo:block padding="5pt"/>
      <fo:block font-size="16pt" text-align="left">
        Upload Documents - test
      </fo:block>
      <fo:block>
        <fo:leader leader-pattern="rule" leader-length="100%" rule-style="solid" rule-thickness="2pt"/>
      </fo:block>
      <fo:block padding="8pt"/>
      <fo:block background-color="#ebe8e8" font-size="10pt" font-weight="bold">
        Document(s)
      </fo:block>
      <fo:block padding="4px" font-size="8pt" font-weight="normal" text-align="center">
        <fo:table>
          <fo:table-column column-width="50%" />
          <fo:table-column column-width="50%" />
          <fo:table-header>
            <fo:table-row>
              <fo:table-cell border-style="solid" padding="2pt">
                <fo:block font-weight="bold">Document Name</fo:block>
              </fo:table-cell>
              <fo:table-cell border-style="solid" padding="2pt">
                <fo:block font-weight="bold">Document Type</fo:block>
              </fo:table-cell>
            </fo:table-row>
          </fo:table-header>
          <fo:table-body>
            <xsl:for-each select="/root/pages/page_12/sections/fwcF17DocumentUpload/data[size &gt; 0]">
              <fo:table-row>
                <fo:table-cell border-style="solid" padding="2pt">
                  <fo:block>
                    <xsl:value-of select="name" />
                  </fo:block>
                </fo:table-cell>
                <fo:table-cell border-style="solid" padding="2pt">
                  <fo:block>
                    <xsl:value-of select="documentType" />
                  </fo:block>
                </fo:table-cell>
              </fo:table-row>
            </xsl:for-each>
          </fo:table-body>
        </fo:table>
      </fo:block>
    </fo:block>
  </xsl:template>
</xsl:stylesheet>

如果您能在您的问题中添加一个最小的 xml-source-sample 以更好地理解您的 xslt，那将非常有帮助。

即：您的模板匹配：<xsl:template match="part35Details"> 看起来有些奇怪。模板不使用上下文。

删除 xsl-fo 中的 table 个单元格

remove table cell in xsl-fo

xslt

xsl-fo