如何在 Android Studio Bumblebee 中添加插件

Question

我想在项目中添加 dagger-hilt 插件。

 classpath 'com.google.dagger:hilt-android-gradle-plugin:2.40.5'

https://developer.android.com/studio/preview/features#settings-gradle

plugins {
    id 'com.android.application' version '7.1.0-beta02' apply false
    id 'com.android.library' version '7.1.0-beta02' apply false
    id 'org.jetbrains.kotlin.android' version '1.5.30' apply false
}

task clean(type: Delete) {
  delete rootProject.buildDir
}

pluginManagement {
  repositories {
    gradlePluginPortal()
    google()
    mavenCentral()
  }
}

dependencyResolutionManagement {
  repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
  repositories {
    google()
    mavenCentral()
  }
}
rootProject.name = 'GradleManagedDeviceTestingNew'
include ':app'

Answer 1

您应该将 resolutionStrategy 添加到 settings.gradle，如下所示。

pluginManagement {
    repositories {
        gradlePluginPortal()
        google()
        mavenCentral()
    }

    resolutionStrategy {
        eachPlugin {
            if (requested.id.id == 'dagger.hilt.android.plugin') {
                useModule("com.google.dagger:hilt-android-gradle-plugin:2.40.5")
            }
        }
    }
}

然后，将如下所示的 hilt 插件添加到模块级别 build.gradle 文件中，它已正确更新。

plugins{
  *****
  id 'dagger.hilt.android.plugin'
}

Answer 2

在 AS BubmleBee 中创建新项目时，top-level gradle 文件

中缺少依赖项块

要解决添加类路径依赖项的问题，您应该在 buildscript 块中添加以下块。

 dependencies {
        classpath "com.google.dagger:hilt-android-gradle-plugin:2.40.5"

    }

Answer 3

这是在 bumblebee 中使用类路径的正确方法

在插件之前使用 buildscript 它将工作并将您的类路径放在依赖项块中

buildscript {
    dependencies {
        classpath("com.google.dagger:hilt-android-gradle-plugin:2.40.5")
    }
}


plugins {
    id 'com.android.application' version '7.1.0-rc01' apply false
    id 'com.android.library' version '7.1.0-rc01' apply false
    id 'org.jetbrains.kotlin.android' version '1.5.30' apply false
}



task clean(type: Delete) {
    delete rootProject.buildDir
}

如何在 Android Studio Bumblebee 中添加插件

How to add plugins in the Android Studio Bumblebee

android

android-studio

android-gradle-plugin

dagger-hilt