单击并识别文本框中的部分文本 vb.net

Question

我正在尝试制作一个程序，该程序使用一个文本框，其中列出了可以单击的文本选项。

以文本框为例：

[选择：<1><2><3>]

所以用户可以然后作为示例点击（在文本上）<2> 到 select 第二个选项或 <3> 所以 select 第三个选项。这个想法来自使用类似系统的 AutoCAD 命令提示符。

如何在 vb.net 代码中实现这样的功能（如果可能的话）？

Answer 1

试试这个：

Private Sub TextBox1_Click(sender As Object, e As EventArgs) Handles TextBox1.Click
    Dim SplitText As String() = TextBox1.Text.Split(CChar("<"), ">")
    Dim SelectedText As String = GetSelectedText()
    Dim Options As New List(Of String)

    If Not SelectedText = "" Then
        For i = 0 To SplitText.Length - 1
            If IsNumeric(SplitText(i)) Then
                Options.Add("<" & SplitText(i) & ">")
            End If
        Next
        For i = 0 To Options.Count - 1
            If SelectedText = Options(i) Then
                'Put your code here if it is the current option in the loop equals the selected option.
                'I added a messagebox just so you can see the current option.
                MessageBox.Show("You selected option: " & Options(i))
            End If
        Next
    End If
End Sub

Private Function GetSelectedText()
    Dim CursorPosition As Integer = TextBox1.SelectionStart
    Dim SelectedNumber As String = ""
    Dim NumberLength As Integer = 0

    If CursorPosition = 0 Or CursorPosition = TextBox1.Text.Length Then
        Return ""
    End If
    Do Until Mid(TextBox1.Text, CursorPosition - NumberLength, 1) = "<"
        NumberLength += 1
    Loop
    SelectedNumber = Mid(TextBox1.Text, CursorPosition - NumberLength, NumberLength + 1)
    NumberLength = 0
    CursorPosition += 1
    Do Until Mid(TextBox1.Text, CursorPosition + NumberLength, 1) = ">"
        NumberLength += 1
    Loop
    SelectedNumber &= Mid(TextBox1.Text, CursorPosition, NumberLength + 1)

    If IsNumeric(SelectedNumber.Remove(0, 1).Remove(SelectedNumber.Length - 2, 1)) Then
        Return SelectedNumber
    Else
        Return ""
    End If
End Function

我把它放在文本框点击事件中，它起作用了。我没有尝试将代码放在任何其他事件中。我假设文本框被命名为：TextBox1.

Answer 2

这里有一个快速示例，展示了如何使用 LinkLabel:

构建“菜单”

Public Class Form1

    Private menuItems() As String = {"cat", "dog", "fish"}

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim menu As String = "Selection: " & String.Join(", ", menuItems)
        LinkLabel1.Text = menu
        LinkLabel1.Links.Clear()
        For Each item In menuItems
            LinkLabel1.Links.Add(menu.IndexOf(item), item.Length)
        Next
    End Sub

    Private Sub LinkLabel1_LinkClicked(sender As Object, e As LinkLabelLinkClickedEventArgs) Handles LinkLabel1.LinkClicked
        Dim i As Integer = LinkLabel1.Links.IndexOf(e.Link)
        Label1.Text = menuItems(i)
    End Sub

End Class

输出：

单击并识别文本框中的部分文本 vb.net

Click and recognize part of text in textbox vb.net

vb.net

string

textbox

mouseover