xsl将子元素分组到父标签中

Question

我需要使用 xslt 将项目标签转换为其各自的父节点。

我有这个输入。

<root>
<field>111</field>
<list1>
    <item>
        <field1>aa</field1>
        <field2>valuea</field2>
    </item>
    <item>
        <field1>bb</field1>
        <field2>valueb</field2>
    </item>
</list1>
<list2>
    <item>
        <field3>cc</field3>
        <field4>valuec</field4>
    </item>
    <item>
        <field3>dd</field3>
        <field4>valued</field4>
    </item>
</list2>

我正在使用此 xsl，但无法正常工作。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>
<xsl:template match="list1/item">
    <list1>
        <xsl:apply-templates select="@*|node()"/>
    </list1>
</xsl:template>
<xsl:template match="list2/item">
    <list2>
        <xsl:apply-templates select="@*|node()"/>
    </list2>
</xsl:template>
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>
<xsl:template match="list1/*">
    <xsl:apply-templates select="node()"/>
</xsl:template>
    <xsl:template match="list2/*">
    <xsl:apply-templates select="node()"/>
</xsl:template>

预期的输出是这样的。

<root>
<field>111</field>
<list1>
    <field1>aa</field1>
    <field2>valuea</field2>
</list1>
<list1>
    <field1>bb</field1>
    <field2>valueb</field2>
</list1>
<list2>
    <field3>cc</field3>
    <field4>valuec</field4>
</list2>
<list2>
    <field3>dd</field3>
    <field4>valued</field4>
</list2>

我尝试使用上面的代码，但它返回的 xml 根本没有父标记。怎么可能做到？

Answer 1

怎么样：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="list1 | list2">
    <xsl:apply-templates/>
</xsl:template>

<xsl:template match="item">
    <xsl:element name="{name(..)}">
        <xsl:apply-templates/>
    </xsl:element>
</xsl:template>

</xsl:stylesheet>

已添加：

it removes the tag list2 if there's no item in it. How can I leave it there?

变化：

<xsl:template match="list1 | list2">

至：

<xsl:template match="list1[item] | list2[item]">

在 XSLT 2.0 中，您可以：

<xsl:template match="(list1 | list2)[item]">

xsl将子元素分组到父标签中

xsl to group child elements into parent tag

xml

xslt

parent