LINQ to DATASET with Group Join and Group By (vb.net)

Question

我有 2 个数据表，正在尝试使用左外连接来汇总其中的数据。使用此代码连接工作正常

Dim Journal = From entries In dt.AsEnumerable()
              Join inccodes In dtGL.AsEnumerable()
              On entries.Field(Of String)("GLCode") Equals inccodes.Field(Of String)("GLCode")                                                                                                                
              Group By keys = New With {Key .IncomeCode = entries.Field(Of String)("GLCode"), Key .IncomeDesc = .inccodes.Field(Of String)("GLCodeDesc")}
              Into ChargeSum = Group, sm = Sum(entries.Field(Of Decimal)("Amount"))
              Where sm <> 0
              Select New GL_Journal With {.IncomeCode = keys.IncomeCode, .IncomeDesc = keys.IncomeDesc, .LineAmount = sm}

                                                      `

但是，因为我真的想要左外连接，所以我想使用组连接而不是连接。一旦我将 Join 更改为 Group 通过“.inccodes.field(Of String)("GLCodeDesc")”加入 Group 中的代码，就会突出显示“.inccodes”并显示错误“'inccodes'”不是 'anonymous type' 的成员” 我已经查看了很多关于 Group By 和 Group Join 的文档，但是关于它们的信息很少。有任何想法吗？我会用方法语法得到更多 options/success 吗？

Answer 1

如果我尝试使用左外连接重现您的查询，我会这样做：

Dim dt As New DataTable
dt.Columns.Add("GLCode", GetType(String))
dt.Columns.Add("Amount", GetType(Decimal))
dt.Rows.Add("111", 3251.21)
dt.Rows.Add("222", 125.79)
dt.Rows.Add("999", 10000)

Dim dtGL As New DataTable
dtGL.Columns.Add("GLCode", GetType(String))
dtGL.Columns.Add("GLCodeDesc", GetType(String))
dtGL.Rows.Add("111", "a")
dtGL.Rows.Add("222", "b")
dtGL.Rows.Add("333", "c")

Dim Journal = From entries In dt.AsEnumerable()
              Group Join inccodes In dtGL.AsEnumerable()
                On entries.Field(Of String)("GLCode") Equals inccodes.Field(Of String)("GLCode")
                Into Group
              From lj In Group.DefaultIfEmpty()              
              Group By keys = New With {Key .IncomeCode = entries.Field(Of String)("GLCode"), Key .IncomeDesc = lj?.Field(Of String)("GLCodeDesc")}
                Into ChargeSum = Group, sm = Sum(entries.Field(Of Decimal)("Amount"))                
              Select New With {.IncomeCode = keys.IncomeCode, .IncomeDesc = keys.IncomeDesc, .LineAmount = sm}

LINQ to DATASET with Group Join and Group By (vb.net)

LINQ to DATASET with Group Join and Group By (vb.net)

linq

vb.net

join