将项目添加到自定义组件的布局

Question

我有一个自定义 Footer Component，我想在我的 QML 应用程序的不同位置重复使用它：

Rectangle {
    color: "gold"
    height: 50
    anchors {
        bottom: parent.bottom
        left: parent.left
        right: parent.right
    }

    RowLayout {
        anchors.fill: parent
        anchors.margins: 10

        Button {
            text: "quit"
        }
    }
}

这个的使用很简单：

Window {
    visible: true

    Footer {
    }
}

但现在我想在一个视图中向 Footer 的 RowLayout 添加一个 "ButtonA"，在另一个视图中添加一个 "ButtonB"。

我怎样才能做到这一点？

Answer 1

参见 this 答案。

您必须在 Footer.qml 中声明一个 default 属性:

import QtQuick 2.0
import QtQuick.Controls 1.2
import QtQuick.Layouts 1.1

Rectangle {
    color: "gold"
    height: 50

    default property alias content: rowLayout.children

    anchors {
        bottom: parent.bottom
        left: parent.left
        right: parent.right
    }

    RowLayout {
        id: rowLayout
        anchors.fill: parent
        anchors.margins: 10

        Button {
            text: "quit"
        }
    }
}

这确保任何声明为 Footer 实例子项的项目都将添加到其 RowLayout。

main.qml:

import QtQuick 2.4
import QtQuick.Controls 1.3

ApplicationWindow {
    width: 640
    height: 480
    visible: true

    StackView {
        id: stackView
        anchors.fill: parent
        initialItem: viewAComponent
    }

    Component {
        id: viewAComponent

        Rectangle {
            id: viewA
            color: "salmon"

            Footer {
                id: footerA

                Button {
                    text: "Go to next view"
                    onClicked: stackView.push(viewBComponent)
                }
            }
        }
    }

    Component {
        id: viewBComponent

        Rectangle {
            id: viewB
            color: "lightblue"

            Footer {
                id: footerB

                Button {
                    text: "Go to previous view"
                    onClicked: stackView.pop()
                }
            }
        }
    }
}

我使用 StackView 作为在视图之间导航的便捷方式。

将项目添加到自定义组件的布局

Adding Items to a layout of a custom component

qt

qml

qtquick2