表格之间单元格的镜像范围

Question

工作表 1

  Private Sub Worksheet_change(ByVal Target As Range)
    
    If Not Intersect(Target, Range("B93")) Is Nothing Then
       If Target = Range("B93") Then
          Sheets("Sheet2").Range("A1").Value = Target.Value
       End If
    End If
    
    End Sub

工作表 2

Private Sub Worksheet_change(ByVal Target As Range)

If Not Intersect(Target, Range("A1")) Is Nothing Then
  If Target = Range("A1") Then
    If Sheets("Sheet1").Range("B93").Value <> Target.Value Then
      Sheets("Sheet1").Range("B93").Value = Target.Value
    End If
  End If
End If

End Sub

该代码仅适用于 B93 和 A1 上的单个单元格。

我尝试在 sheet1 上将范围设置为 Range("B93:N122") 并在 sheet 2 上将范围设置为 Range("A1:M22") 以反映发生变化时的范围但是我收到错误 13 不匹配。

目标：我想反映 range(A1:M22) sheet 1 到 sheet 2 上的变化（双向），反之亦然。我缺少哪一行代码？

Answer 1

镜像范围

在一个工作表的单元格中更改的值也会在另一个工作表的相同单元格中更改为相同的值，反之亦然。

标准模块Module1

Option Explicit

Sub MirrorWorksheets( _
        ByVal Target As Range, _
        ByVal RangeAddress As String, _
        ByVal WorksheetName As String)
    
    Dim sws As Worksheet: Set sws = Target.Worksheet
    Dim irg As Range: Set irg = Intersect(sws.Range(RangeAddress), Target)
    If irg Is Nothing Then Exit Sub
    
    Dim dws As Worksheet: Set dws = sws.Parent.Worksheets(WorksheetName) 
    
    Application.EnableEvents = False
    
    Dim iarg As Range

    For Each iarg In irg.Areas
        dws.Range(iarg.Address).Value = iarg.Value
    Next iarg

    Application.EnableEvents = True
    
End Sub

Sheet1 模块

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    MirrorWorksheets Target, "A1:M22,B93:N122", "Sheet2"
End Sub

Sheet2 模块

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    MirrorWorksheets Target, "A1:M22,B93:N122", "Sheet1"
End Sub

表格之间单元格的镜像范围

Mirroring Range of Cells in Between Sheets

excel

vba

range

cell

镜像范围