使用 CMake 的 find_package，为什么版本范围 0.3.3...<0.5.0 不接受 0.4.6？

Question

我希望我的存储库依赖于具有特定允许版本范围的包。所以，看着 documentation，我写：

find_package(mypkg 0.3.3...<0.5.0 REQUIRED)

但是当我使用 CMake (v3.23.0-rc2) 配置时，这一行产生：

CMake Error at CMakeLists.txt:24 (find_package):
  Could not find a configuration file for package "mypkg" that is
  compatible with requested version range "0.3.3...<0.5.0".

  The following configuration files were considered but not accepted:

    /opt/mypkg/lib64/cmake/mypkg/mypkg-config.cmake, version: 0.4.6

为什么 0.4.6 与 0.3.3...<0.5.0 不兼容？或者 - 还有其他问题吗？

附加信息：

正在使用的回购 CMakeLists.txt 有：
```
cmake_minimum_required(VERSION 3.18 FATAL_ERROR)
```
...将其更改为 3.19 没有帮助。
应大家的要求，这里是包自动生成的版本配置文件：

# This is a basic version file for the Config-mode of find_package().
# It is used by write_basic_package_version_file() as input file for configure_file()
# to create a version-file which can be installed along a config.cmake file.
#
# The created file sets PACKAGE_VERSION_EXACT if the current version string and
# the requested version string are exactly the same and it sets
# PACKAGE_VERSION_COMPATIBLE if the current version is >= requested version,
# but only if the requested major and minor versions are the same as the current
# one.
# The variable CVF_VERSION must be set before calling configure_file().


set(PACKAGE_VERSION "0.4.6")

if(PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION)
  set(PACKAGE_VERSION_COMPATIBLE FALSE)
else()

  if("0.4.6" MATCHES "^([0-9]+)\.([0-9]+)")
    set(CVF_VERSION_MAJOR "${CMAKE_MATCH_1}")
    set(CVF_VERSION_MINOR "${CMAKE_MATCH_2}")

    if(NOT CVF_VERSION_MAJOR VERSION_EQUAL 0)
      string(REGEX REPLACE "^0+" "" CVF_VERSION_MAJOR "${CVF_VERSION_MAJOR}")
    endif()
    if(NOT CVF_VERSION_MINOR VERSION_EQUAL 0)
      string(REGEX REPLACE "^0+" "" CVF_VERSION_MINOR "${CVF_VERSION_MINOR}")
    endif()
  else()
    set(CVF_VERSION_MAJOR "0.4.6")
    set(CVF_VERSION_MINOR "")
  endif()

  if(PACKAGE_FIND_VERSION_RANGE)
    # both endpoints of the range must have the expected major and minor versions
    math (EXPR CVF_VERSION_MINOR_NEXT "${CVF_VERSION_MINOR} + 1")
    if (NOT (PACKAGE_FIND_VERSION_MIN_MAJOR STREQUAL CVF_VERSION_MAJOR
          AND PACKAGE_FIND_VERSION_MIN_MINOR STREQUAL CVF_VERSION_MINOR)
        OR ((PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "INCLUDE"
            AND NOT (PACKAGE_FIND_VERSION_MAX_MAJOR STREQUAL CVF_VERSION_MAJOR
              AND PACKAGE_FIND_VERSION_MAX_MINOR STREQUAL CVF_VERSION_MINOR))
          OR (PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "EXCLUDE"
            AND NOT PACKAGE_FIND_VERSION_MAX VERSION_LESS_EQUAL ${CVF_VERSION_MAJOR}.${CVF_VERSION_MINOR_NEXT})))
      set(PACKAGE_VERSION_COMPATIBLE FALSE)
    elseif(PACKAGE_FIND_VERSION_MIN_MAJOR STREQUAL CVF_VERSION_MAJOR
        AND PACKAGE_FIND_VERSION_MIN_MINOR STREQUAL CVF_VERSION_MINOR
        AND ((PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_LESS_EQUAL PACKAGE_FIND_VERSION_MAX)
        OR (PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "EXCLUDE" AND PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION_MAX)))
      set(PACKAGE_VERSION_COMPATIBLE TRUE)
    else()
      set(PACKAGE_VERSION_COMPATIBLE FALSE)
    endif()
  else()
    if(NOT PACKAGE_FIND_VERSION_MAJOR VERSION_EQUAL 0)
      string(REGEX REPLACE "^0+" "" PACKAGE_FIND_VERSION_MAJOR "${PACKAGE_FIND_VERSION_MAJOR}")
    endif()
    if(NOT PACKAGE_FIND_VERSION_MINOR VERSION_EQUAL 0)
      string(REGEX REPLACE "^0+" "" PACKAGE_FIND_VERSION_MINOR "${PACKAGE_FIND_VERSION_MINOR}")
    endif()

    if((PACKAGE_FIND_VERSION_MAJOR STREQUAL CVF_VERSION_MAJOR) AND
        (PACKAGE_FIND_VERSION_MINOR STREQUAL CVF_VERSION_MINOR))
      set(PACKAGE_VERSION_COMPATIBLE TRUE)
    else()
      set(PACKAGE_VERSION_COMPATIBLE FALSE)
    endif()

    if(PACKAGE_FIND_VERSION STREQUAL PACKAGE_VERSION)
      set(PACKAGE_VERSION_EXACT TRUE)
    endif()
  endif()
endif()


# if the installed project requested no architecture check, don't perform the check
if("FALSE")
  return()
endif()

# if the installed or the using project don't have CMAKE_SIZEOF_VOID_P set, ignore it:
if("${CMAKE_SIZEOF_VOID_P}" STREQUAL "" OR "8" STREQUAL "")
  return()
endif()

# check that the installed version has the same 32/64bit-ness as the one which is currently searching:
if(NOT CMAKE_SIZEOF_VOID_P STREQUAL "8")
  math(EXPR installedBits "8 * 8")
  set(PACKAGE_VERSION "${PACKAGE_VERSION} (${installedBits}bit)")
  set(PACKAGE_VERSION_UNSUITABLE TRUE)
endif()

Answer 1

简而言之：从为包指定的兼容性策略来看，版本范围0.3.3...<0.5.0是不正确的。仅当请求中的主要版本和次要版本与包的版本相同时，才会将给定的包视为兼容。

正确的版本请求可能是：

0.3.3...<0.4.0
0.4.3...<0.5.0

（但是0.4.6版本的包只能满足第二个请求）

详情

配置文件由 write_basic_package_version_file 使用兼容性选项 SameMinorVersion 生成。这可以从描述中推断出来：

# ... it sets
# PACKAGE_VERSION_COMPATIBLE if the current version is >= requested version,
# but only if the requested major and minor versions are the same as the current
# one.

如果请求的版本范围包含两端（不包含 <），则两端应包含 相同的主要和次要版本:

# both endpoints of the range must have the expected major and minor versions

当排除上端（<）时，它的次版本可能比下端大 1。

允许：

3.3.0...3.3.5
3.4.2...3.4.10
3.3.0...<3.3.5
3.3.2...<3.4

不允许：

3.3.0...3.4.0
3.3.0...4.3.0
3.3.0...<3.5
3.3.0...<3.4.1

只有在允许版本范围时，才会检查包的版本是否在范围内。在其他情况下，包裹被视为与请求 不兼容。

据我了解，find_package 调用中的版本请求 semantic 是：

如果请求的是单一版本，包版本应与请求的版本兼容。并且包版本不能低于要求的版本。
如果版本范围没有 <，包的版本应该两端兼容。并且包版本应该属于范围。
在版本范围为 < 的情况下，上限可能表示软件包的“下一个不兼容”版本。在其他方面，这种情况类似于没有 <.

使用 CMake 的 find_package，为什么版本范围 0.3.3...<0.5.0 不接受 0.4.6？

With CMake's find_package, why does version range 0.3.3...<0.5.0 not accept 0.4.6?

versioning

cmake

dependency-management

buildconfiguration

详情