当使用键盘打开弹出窗口时，如何使 Tpopupmenu 成为 select 第一个菜单条目

Question

TPopupMenu 中的项目可以highlighted/selected 键盘或鼠标。使用键盘选择时，您可以使用箭头键在菜单中移动。

如何在不使用 VK_DOWN 模拟向下箭头按键的情况下将第一个菜单项标记为选中（蓝色）（参见下面的代码）？

Popup := TPopupMenu.create(nil);
Popup.OnPopup := PopupClick;
class procedure TTrayMain.PopupClick(Sender: TObject) ;
begin    
  // Code below activates the first menu entry.. 
  // Now Looking for an alternative solution to replace this hack:
  keybd_event( VK_DOWN, MapVirtualKey( VK_DOWN,0), 0, 0);
  keybd_event( VK_DOWN, MapVirtualKey( VK_DOWN,0), KEYEVENTF_KEYUP, 0);

end;

Answer 1

我相信你被假输入困住了。我认为您可以 PostMessage 将 down/up 消息发送到 GetFocus。这使得它至少是本地黑客而不是全球黑客。您可能需要一个钩子来捕获正确的消息以触发黑客攻击。

理想情况下，这应该被记录下来 here，但遗憾的是它没有。要确定 Microsoft 是如何做到这一点的唯一方法是在 98/2000/XP 中调试 Explorer。这些系统在 Explorer 和 Internet Explorer 中的菜单实现是从工具栏按钮下拉的上下文菜单，伪装菜单栏。

Answer 2

您需要将未记录的 MN_SELECITEM 消息发送到弹出窗口。

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Menus, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    PopupMenu1: TPopupMenu;
    Item1: TMenuItem;
    Item2: TMenuItem;
    Item3: TMenuItem;
  private
    { Private declarations }
  public
    { Public declarations }
  end;

  //To override the default PopupList, based on Remy Lebeau's code
  TPopupListEx = class(TPopupList)
  protected
    procedure WndProc(var Message: TMessage); override;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

const MN_SELECTITEM = E5;

{ TPopupListEx }

procedure TPopupListEx.WndProc(var Message: TMessage);
var hm:HMENU;

begin
  inherited;
  if (Message.Msg = WM_ENTERMENULOOP) and (Message.WParam = 1) then
    begin
      //When the popupwindow is already created, we can ask it's handle
      hm:=FindWindow(PChar('#32768'),nil);
      //Send the MN_SELECTITEM message. The third parameter is the desired menuitem's index.
      SendMessage(hm,MN_SELECTITEM,0,0);
    end;
end;

initialization
  Popuplist.Free; //free the "default", "old" list
  PopupList := TPopupListEx.Create; //create the new one
  // The new PopupList will be freed by
  // finalization section of Menus unit.
end.

关于其他（包括提到的 delphipraxis 示例）解决方案的注意事项：

使用 SetMenuItemInfoW 或 HiliteMenuItem 将 MenuItem 设置为突出显示状态将不起作用，因为它只会影响外观，但是当您将鼠标悬停在任何其他项目，第一项保持突出显示。

当使用键盘打开弹出窗口时，如何使 Tpopupmenu 成为 select 第一个菜单条目

How to make Tpopupmenu to pre-select the 1st menu entry when a popup is opened with the keyboard

delphi

winapi

delphi-7

delphi-2010