Excel VBA 拼写检查太慢了

Question

我有一个电子表格，其中将 5 列数据的所有排列列为一个文本列（X 列又名 24），我的目标是仅将该列表中的实际单词提取到它自己的列（Y 列又名）中25).第一部分不是用 VBA 执行的，几乎是瞬间发生的，但是拼写检查 + 提取实际单词需要一个多小时才能完成（我不得不在 10 分钟后停止它，甚至不到 10%通过的方式）。有更好的方法吗？

我的列表从第 6 行开始 (n = 6)，Range("V3") 只是排列数（在本例中为 83,521）。

Sub Permute_and_Extract()

n = 6

Range("X7:X1000000").ClearContents
Range("Y6:Y1000000").ClearContents

Max = Range("V3") + 5
Range("X6").Select
Selection.AutoFill Destination:=Range("X6:X" & Max)

For i = 6 To Max
x = Application.CheckSpelling(Cells(i, 24).Text)
If x = True Then
Cells(n, 25) = Cells(i, 24)
n = n + 1
End If
Next i


End Sub

Answer 1

根据以上评论：

Sub Permute_and_Extract()

    Const RNG As String = "F1:F10000"
    Dim wlist As Object, t, c As Range, i As Long, arr, res
    Dim rngTest As Range
    
    Set rngTest = ActiveSheet.Range(RNG)
    
    t = Timer
    Set wlist = WordsList("C:\Temp\words.txt", 5)
    Debug.Print "loaded list", Timer - t
    Debug.Print wlist.Count, "words"
    
    'using an array approach...
    t = Timer
    arr = rngTest.Value
    For i = 1 To UBound(arr, 1)
        res = wlist.exists(arr(i, 1))
    Next i
    Debug.Print "Array check", Timer - t
    
    'going cell-by-cell...
    t = Timer
    For Each c In rngTest.Cells
        res = wlist.exists(c.Value)
    Next c
    Debug.Print "Cell by cell", Timer - t
    
End Sub

'return a dictionary of words of length `wordLen` from file at `fPath`
Function WordsList(fPath As String, wordLen As Long) As Object
    Dim dict As Object, s As String
    Set dict = CreateObject("scripting.dictionary")
    dict.comparemode = vbTextCompare   'case-insensitive !!!
    With CreateObject("scripting.filesystemobject").opentextfile(fPath)
        Do While Not .AtEndOfStream
            s = .readline()
            If Len(s) = wordLen Then dict.Add s, True
        Loop
        .Close
    End With
    Set WordsList = dict
End Function

输出：

loaded list    0.359375 
 8938         words
Array check    0.019 
Cell by cell   0.030

Excel VBA 拼写检查太慢了

Excel VBA Spellcheck Way Too Slow

excel

vba

spell-checking