XSLT 根据条件对兄弟姐妹进行分组？

Question

谁能帮我解决一个未完成的想法？

我不太习惯 xslt，但我正在尝试并且感谢很多互联网帮助我相处得很好。

但是：

以下情况我无法解决：

举个例子 XML 一些地质层数据看起来像这样：

  <LAYERS> 
    <LAYER DEPTHTO="1.00" PETRO="Sand" STRAT="geologiscal_formation_1" INTV="1"/>
    <LAYER DEPTHTO="94.00" PETRO="Sand" STRAT="geologiscal_formation_1" INTV="1"/>
    <LAYER DEPTHTO="94.20" INTV="1" INDEX_ZONE="-1" EGART="Lost_Data"/>
    <LAYER DEPTHTO="95.00" PETRO="Gravel" STRAT="geologiscal_formation_1" INTV="1"/>
    <LAYER DEPTHTO="100.00" PETRO="Sand" STRAT="geologiscal_formation_2" INTV="1"/>
    <LAYER DEPTHTO="100.50" PETRO="Mud" STRAT="geologiscal_formation_2" INTV="1"/>
    <LAYER DEPTHTO="101.50" PETRO="Sand" STRAT="geologiscal_formation_2" INTV="1"/>
    <LAYER DEPTHTO="101.80" PETRO="Mud" STRAT="geologiscal_formation_2" INTV="1"/>
    <LAYER DEPTHTO="102.90" PETRO="Mud" STRAT="geologiscal_formation_3" INTV="1"/>
    <LAYER DEPTHTO="103.00" PETRO="Sand" STRAT="geologiscal_formation_3" INTV="1"/>
    <LAYER DEPTHTO="103.25" INTV="1" INDEX_ZONE="-1" EGART="Lost_Data"/>
    <LAYER DEPTHTO="103.69" PETRO="Sand" STRAT="geologiscal_formation_3" INTV="1"/>
    <LAYER DEPTHTO="104.00" PETRO="Mud" STRAT="geologiscal_formation_3" INTV="1"/>
</LAYERS>

并使用以下 xslt 代码：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xml="http://www.w3.org/XML/1998/namespace"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" exclude-result-prefixes=" xml xsl xs">
    <xsl:output method="text" version="1.0" indent="yes" />
    <xsl:key name="adj" match="LAYER" use="generate-id(preceding-sibling::LAYER[not(@STRAT = current()/@STRAT)][1])" />
    <xsl:template match="/*">

        <xsl:for-each select="LAYER[generate-id() = generate-id(key('adj', generate-id(preceding-sibling::LAYER[not(@STRAT = current()/@STRAT)][1]))[1])]">
            <xsl:variable name="INTVID" select="@INTV"/>
            <xsl:variable name="precedingZone" select="preceding-sibling::LAYER[@INTV = $INTVID][1]"/>
            <xsl:variable name="DEPTHFROM" select="$precedingZone/@DEPTHTO"/>
            
                <xsl:if test="@STRAT != ''">
                    <xsl:variable name="current-group" select="key('adj', generate-id(preceding-sibling::LAYER[not(@STRAT = current()/@STRAT)][1]))" />
                    <xsl:text>ZONE "</xsl:text>
                    <xsl:value-of select="@STRAT"/>
                    <xsl:text>" </xsl:text>
                    <xsl:for-each select="$current-group">
                        <xsl:sort select="$DEPTHFROM" data-type="number" order="ascending"/>
                        <xsl:if test="position() = 1 ">
                            <xsl:value-of select="$DEPTHFROM"/>
                        </xsl:if>
                    </xsl:for-each>
                    <xsl:text> </xsl:text>
                    <xsl:for-each select="$current-group">
                        <xsl:sort select="@DEPTHTO" data-type="number" order="descending"/>
                        <xsl:if test="position() = 1 ">
                            <xsl:value-of select="@DEPTHTO"/>
                        </xsl:if>
                    </xsl:for-each>
                    <xsl:text> </xsl:text>
                    <xsl:value-of select="@INDEX_ZONE"/>
                    <xsl:text>&#10;</xsl:text>
                </xsl:if>
        </xsl:for-each>
        
    </xsl:template>
</xsl:stylesheet>

结果看起来像这样：

ZONE "geologiscal_formation_1"  94.00 
ZONE "geologiscal_formation_1" 94.20 95.00 
ZONE "geologiscal_formation_2" 95.00 101.80 
ZONE "geologiscal_formation_3" 101.80 103.00 
ZONE "geologiscal_formation_3" 103.25 104.00

但所需的输出应如下所示：

ZONE "geologiscal_formation_1" 0.00 95.00
ZONE "geologiscal_formation_2" 95.00 101.80 
ZONE "geologiscal_formation_3" 101.80 104.00

更多背景信息：由于第一行只给出了 DEPTHTO 数据，我假设它从 0 开始，只要不知道。分组只部分起作用，因为我们得到了一些带有“lost_data”的层，这使所有的想法都变成了糟糕的结果。

所以我需要某种条件，即 ignores/skips 找到“lost_data”的数据。但是由于我使用的是“for-each”，所以我不知道如何实现。我听说过一些“管道处理”，但没有深入研究，因为我已经被我得到的东西淹没了。

也许有人知道得更多？

是的，我卡在了 xslt 1.0 :)

感谢任何想法或帮助。

多亏了答案和一些小改动，我才能够实现我的目标：

变化看起来像这样：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
  xmlns:xml="http://www.w3.org/XML/1998/namespace"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" exclude-result-prefixes=" xml xsl xs">
  <xsl:output method="text" version="1.0" indent="yes" />
  <xsl:key name="layer-by-strat" match="LAYER" use="@STRAT" />
  <xsl:template match="/*">
    <xsl:for-each select="LAYER[not(@EGART='Lost_Data')][count(. | key('layer-by-strat', @STRAT)[1]) = 1]">
      <xsl:variable name="INTVID" select="@INTV"/>
      <xsl:variable name="precedingZone" select="preceding-sibling::LAYER[@INTV = $INTVID][1]"/>
      <xsl:variable name="DEPTHFROM" select="$precedingZone/@DEPTHTO"/>
      <xsl:choose>
        <xsl:when test="$precedingZone">
          <xsl:text>ZONE "</xsl:text>
          <xsl:value-of select="@STRAT" />
          <xsl:text>" </xsl:text>
          <xsl:value-of select="$DEPTHFROM"/>
          <xsl:text> </xsl:text>
          <xsl:value-of select="key('layer-by-strat', @STRAT)[last()]/@DEPTHTO" />
          <xsl:text>&#10;</xsl:text>
        </xsl:when>
        <xsl:otherwise>
          <xsl:text>ZONE "</xsl:text>
          <xsl:value-of select="@STRAT" />
          <xsl:text>" 0.00 </xsl:text>
          <xsl:value-of select="key('layer-by-strat', @STRAT)[last()]/@DEPTHTO" />
          <xsl:text>&#10;</xsl:text>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

Answer 1

您显示的结果可以很容易地产生，使用：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:key name="layer-by-strat" match="LAYER" use="@STRAT" />

<xsl:template match="LAYERS" >
    <xsl:for-each select="LAYER[not(@EGART='Lost_Data')][count(. | key('layer-by-strat', @STRAT)[1]) = 1]">
        <xsl:text>ZONE "</xsl:text>
        <xsl:value-of select="@STRAT" />
        <xsl:text>" 0.00 </xsl:text>
        <xsl:value-of select="key('layer-by-strat', @STRAT)[last()]/@DEPTHTO" />
        <xsl:text>&#10;</xsl:text>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

这是假设每个组中的最后一个 LAYER 具有所需的最大值 - 否则将需要进行较小的调整。

已添加：

我注意到我错过了要求的一部分，即每一层都从前一层的最大深度开始。这是调整后的样式表：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:key name="layer-by-strat" match="LAYER" use="@STRAT" />

<xsl:template match="LAYERS" >
    <xsl:call-template name="generate-rows">
        <xsl:with-param name="layers" select="LAYER[not(@EGART='Lost_Data')][count(. | key('layer-by-strat', @STRAT)[1]) = 1]"/>
    </xsl:call-template>
</xsl:template>

<xsl:template name="generate-rows">
    <xsl:param name="layers" select="/.."/>
    <xsl:param name="accumulated-depth" select="'0.00'"/>
    <xsl:if test="$layers">
        <xsl:variable name="strat" select="$layers[1]/@STRAT" />
        <xsl:variable name="max-depth" select="key('layer-by-strat', $strat)[last()]/@DEPTHTO" />
        <!-- output -->
        <xsl:text>ZONE "</xsl:text>
        <xsl:value-of select="$strat" />
        <xsl:text>" </xsl:text>
        <xsl:value-of select="$accumulated-depth" />
        <xsl:text> </xsl:text>
        <xsl:value-of select="$max-depth" />
        <xsl:text>&#10;</xsl:text>
        <!-- recursive call -->
        <xsl:call-template name="generate-rows">
            <xsl:with-param name="layers" select="$layers[position() > 1]"/>
            <xsl:with-param name="accumulated-depth" select="$max-depth"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

XSLT 根据条件对兄弟姐妹进行分组？

XSLT grouping siblings with conditions?

xml

xslt

xslt-1.0

已添加：