XSLT 中的多个计数器

Question

我需要在我的 xslt 中维护 2 个计数器 - EntryID 和 RowID。我有一个 xml，其中包含此人持有的姓名和证书。现在我需要为每个人维护一个计数器 (EntryID)，为每个证书维护一个计数器 (RowID)。在认证之上，我需要再添加一个认证“新”，它的 RowID 比此人持有的最大认证数高一个数字。

下面是XML:

<?xml version='1.0' encoding='UTF-8'?>
<wd:Report_Data xmlns:wd="urn:com.workday.report/bsvc">
    <wd:Report_Entry>
        <Name>Ram</Name>
        <Certifications>
            <Certificate>AWS</Certificate>
            <Certificate>Workday</Certificate>
            <Certificate>SAP</Certificate>
        </Certifications>    
    </wd:Report_Entry>
    <wd:Report_Entry>
        <Name>Nitin</Name>
        <Certifications>
            <Certificate>Workday</Certificate>
        </Certifications>    
    </wd:Report_Entry>
    <wd:Report_Entry>
        <Name>Joe</Name>
        <Certifications>
            <Certificate>SAP</Certificate>
            <Certificate>AWS</Certificate>
        </Certifications>    
    </wd:Report_Entry>
</wd:Report_Data>

预期输出如下。该名称应仅出现在第一行。

EntryID,Name,RowID,Certification
1,Ram,1,AWS
1,,2,Workday
1,,3,SAP
1,,4,NEW          --> New certificate with row id 4 as Ram already has 3 certifications
2,Nitin,1,Workday --> Entry ID is 2 for Nitin and Row ID restarts from 1
2,,2,NEW          
3,Joe,1,SAP
3,,2,AWS
3,,3,NEW

到目前为止，我能够构建 XSLT，但没有提供所需的输出。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:wd="urn:com.workday.report/bsvc" 
    xmlns:etv="urn:com.workday/etv"  
    exclude-result-prefixes="xs wd" version="3.0">
   
    <xsl:output method="text" indent="yes"/>  
    
    <xsl:template match="/">
        <xsl:variable name="delimeter" select="','"/>
        <xsl:variable name="lineFeed" select="'&#xa;'"/>
        <root>                
            <xsl:for-each select="wd:Report_Data/wd:Report_Entry">
                
                <EntryID><xsl:value-of select="position()"/></EntryID>
                <xsl:value-of select="$delimeter"/>
                
                <Name><xsl:value-of select="Name"/></Name>
                <xsl:value-of select="$delimeter"/>                    
                
                <xsl:for-each select="Certifications/Certificate"> 
                    <RowID><xsl:value-of select="position()"/></RowID>
                    <xsl:value-of select="$delimeter"/>
                    <xsl:value-of select="."/>
                </xsl:for-each>
                <xsl:value-of select="$lineFeed"/>
                
                <EntryID><xsl:value-of select="position()"/></EntryID>
                <xsl:value-of select="$delimeter"/>
                <xsl:value-of select="$delimeter"/>
                <text>NEW</text>
                <xsl:value-of select="$lineFeed"/>                                 
            </xsl:for-each>                
        </root>            
    </xsl:template>        
</xsl:stylesheet>

请帮助我正确的 XSLT。

Answer 1

要使用 XSLT 3 生成所需的输出，我会使用类似

的东西

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="3.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="#all"
  xmlns:wd="urn:com.workday.report/bsvc"
  expand-text="yes">
  
  <xsl:param name="delimeter" select="','"/>
  <xsl:param name="lineFeed" select="'&#xa;'"/>

  <xsl:output method="text"/>
  
  <xsl:template match="wd:Report_Data">
    <xsl:value-of select="'EntryID','Name','RowID','Certification'" separator="{$delimeter}"/>
    <xsl:value-of select="$lineFeed"/>
    <xsl:apply-templates select="wd:Report_Entry"/>
  </xsl:template>
  
  <xsl:template match="wd:Report_Entry">
    <xsl:apply-templates select="Certifications/Certificate"/>
  </xsl:template>
  
  <xsl:template match="Certificate">
    <xsl:variable name="entry-id" as="xs:integer">
      <xsl:number count="wd:Report_Entry"/>
    </xsl:variable>
    <xsl:variable name="row-id" as="xs:integer">
      <xsl:number/>
    </xsl:variable>
    <xsl:value-of select="$entry-id, (../../Name[$row-id = 1], '')[1], $row-id, ." separator="{$delimeter}"/>
    <xsl:value-of select="$lineFeed"/>
    <xsl:if test="position() = last()">
      <xsl:value-of select="$entry-id, '', $row-id + 1, 'NEW'" separator="{$delimeter}"/>
      <xsl:value-of select="$lineFeed"/>      
    </xsl:if>
  </xsl:template>
  
</xsl:stylesheet>

Answer 2

您显示的 XML 结果可以很容易地产生，使用：

XSLT 1.0

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:wd="urn:com.workday.report/bsvc" 
exclude-result-prefixes="wd">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/wd:Report_Data">
    <root>
        <xsl:for-each select="wd:Report_Entry">
            <row>
                <EntryID>
                    <xsl:value-of select="position()" />
                </EntryID>
                <Name>
                    <xsl:value-of select="Name" />
                </Name>
                <xsl:for-each select="Certifications/Certificate">
                    <Certificate>
                        <RowID>
                            <xsl:value-of select="position()" />
                        </RowID>
                        <cName>
                            <xsl:value-of select="." />
                        </cName>
                    </Certificate>
                </xsl:for-each>
                <Certificate>
                    <RowID>
                        <xsl:value-of select="count(Certifications/Certificate) + 1" />
                    </RowID>
                    <cName>NEW</cName>
                </Certificate>
            </row>
        </xsl:for-each>
    </root>
</xsl:template>

</xsl:stylesheet>

要获得“平面”CSV 输出，您可以这样做：

XSLT 1.0

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:wd="urn:com.workday.report/bsvc">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:template match="/wd:Report_Data">
    <!-- header -->
    <xsl:text>EntryID,Name,RowID,Certification&#10;</xsl:text>
    <!-- data -->
    <xsl:for-each select="wd:Report_Entry">
        <xsl:variable name="entry-data">
            <xsl:value-of select="position()" />
            <xsl:text>,</xsl:text>
            <xsl:value-of select="Name" />
            <xsl:text>,</xsl:text>
        </xsl:variable>
        <!-- output -->
        <xsl:for-each select="Certifications/Certificate">
            <xsl:copy-of select="$entry-data"/>
            <xsl:value-of select="position()" />
            <xsl:text>,</xsl:text>
            <xsl:value-of select="." />
            <xsl:text>&#10;</xsl:text>
        </xsl:for-each>
        <!-- new certificate -->
        <xsl:copy-of select="$entry-data"/>
        <xsl:value-of select="count(Certifications/Certificate) + 1" />
        <xsl:text>,NEW&#10;</xsl:text>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

在 XSLT 3.0 中可以简化为：

<xsl:stylesheet version="3.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:wd="urn:com.workday.report/bsvc" 
expand-text="yes">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:template match="/wd:Report_Data">
    <!-- header -->
    <xsl:text>EntryID,Name,RowID,Certification&#10;</xsl:text>
    <!-- data -->
    <xsl:for-each select="wd:Report_Entry">
        <xsl:variable name="entry-data">{position()},{Name}</xsl:variable>
        <!-- output -->
        <xsl:for-each select="Certifications/Certificate, 'NEW'">{$entry-data},{position()},{.}&#10;</xsl:for-each>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

XSLT 中的多个计数器

Multiple Counters in XSLT

xslt

counter

xslt-3.0