Google sheet 查询 2 列作为搜索关键字并搜索

Question

我在使用 google sheet 函数时遇到了一些问题。

我有 2 个 table。我想在 table2 中搜索 table1 Date+User 作为键值。示例：

Date      User  Unit
2022/05/30  A   109
2022/05/30  B   119
2022/05/30  C   119
2022/05/29  D   109
2022/05/29  E   114

Date      User  Amount
2022/05/30  A   1
2022/05/30  B   2
2022/05/30  C   3
2022/05/30  D   41
2022/05/30  E   5
2022/05/29  D   6
2022/05/29  E   7
2022/05/29  F   81
2022/05/29  G   9
2022/05/29  A   101
2022/05/29  B   11
2022/05/29  C   121
2022/05/29  D   13

查询后我希望 table 看起来像

Hope Result         
Date       User Unit    Amount
2022/05/30  A   109       1
2022/05/30  B   119       2
2022/05/30  C   119       3
2022/05/29  D   109       6
2022/05/29  E   114       7

这是一个示例 google sheet https://docs.google.com/spreadsheets/d/1oxhWMVPt-GziG10agob-xbiNYfKrZVFK9ro0Pj7tn6Y/edit#gid=0

我可以寻求帮助吗？

非常感谢

Answer 1

两种选择。第一个提取 DATE 和 USER

的所有匹配组合

=ARRAYFORMULA(
  QUERY(
   {E2:G,
    IF(ISBLANK(E2:E),,
     IFERROR(
      VLOOKUP(
       E2:E&"|"&F2:F,
       {A2:A&"|"&B2:B,C2:C},
       2,FALSE)))},
   "select Col1, Col2, Col4, Col3
    where Col4 is not null
    label
     Col1 'Date',
     Col2 'User',
     Col3 'Amount',
     Col4 'Unit'"))

哪个returns

Date	User	Unit	Amount
2022/05/30	A	109	1
2022/05/30	B	119	2
2022/05/30	C	119	3
2022/05/29	D	109	6
2022/05/29	E	114	7
2022/05/29	D	109	13

第二个与您的输出完全匹配，但确实省略了第 29 (13) 个的第二个 D 值

=ARRAYFORMULA(
  QUERY(
   {IFERROR(
     VLOOKUP(
      UNIQUE(E2:E&"|"&F2:F),
      {E2:E&"|"&F2:F,E2:G},
      {2,3,4},FALSE)),
    IFERROR(
     VLOOKUP(
      UNIQUE(E2:E&"|"&F2:F),
      {A2:A&"|"&B2:B,C2:C},
      2,FALSE))},
   "where Col4 is not null
    format Col1 'yyyy/mm/dd'"))

两者都已添加到您的 sheet。如果其中任何一个适合你，我可以分解它。

Google sheet 查询 2 列作为搜索关键字并搜索

Google sheet query 2 columns as search key and search

spreadsheet

google-sheets-formula