Delphi Rest.JSON JsonToObject 仅适用于 f 变量

Question

我正在使用 Delphi XE8。

我只是在看 REST.Json ObjectToJsonString() 和 JsonToObject() 调用。

主要是想做这样的事情：

How to convert an object to JSON and back with a single line of code

我注意到我只能让以 F 字符开头的变量起作用。我找不到任何关于此的文档。这是预期的行为吗？我是否应该在 classes 中以 F 开头命名所有变量？如果是，有人可以解释为什么吗？

我创建了一个classTTestJSON，定义了两个成员变量，分别设置为'WORKS'和'FAILS'.

然后我从对象创建了一个 JSON 字符串值：

{
  "varThatWorksBeacuseItStartsWithF":"WORKS",
  "sVarThatFailsBecauseItStartsWithS":"FAILS"
}

从 JSON 字符串返回到对象时，只有 fVarThatWorksBeacuseItStartsWithF 变量被正确重置。在下面的代码中，test := TJson.JsonToObject<TTestJSON>(JsonStr); 使用上面的 JSON，请注意 sVarThatFailsBecauseItStartsWithS 是 "" 而不是 "FAILS".

procedure TForm3.btn1Click(Sender: TObject);
var
  test : TTestJSON;
  JsonStr : String;
begin
  m1.Clear;
  test := TTestJSON.Create;
  try
    test.fVarThatWorksBeacuseItStartsWithF := 'WORKS';
    test.sVarThatFailsBecauseItStartsWithS := 'FAILS';
    JsonStr := TJson.ObjectToJsonString( test );
  finally
    test.Free;
  end;
  m1.Lines.Add(  '** JSONStr Value START **' + #13#10 + JsonStr + '** JSONStr Value END **' + #13#10 );

  test := TJson.JsonToObject<TTestJSON>(JsonStr);
  try
    m1.Lines.Add('** Obj loaded from JSON String Start **' + #13#10 + TJson.ObjectToJsonString( test ) + #13#10 + '** Obj loaded from JSON String End **');
  finally
    test.Free;
  end;
end;

从结果来看，f开头的var把JSON字符串中的f去掉了，s开头的还有它在那里。我原以为第二个结果会是这样的：

{
  "varThatWorksBeacuseItStartsWithF":"WORKS",
  "sVarThatFailsBecauseItStartsWithS":"FAILS"
}

这是要重现的完整代码——只有一个按钮和一个 vcl 表单上的备忘录——还使用了 REST.Json:

unit Main;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, rest.Json;

type
  TTestJSON = class
    fVarThatWorksBeacuseItStartsWithF : String;
    sVarThatFailsBecauseItStartsWithS : String;
  end;

  TForm3 = class(TForm)
    btn1: TButton;
    m1: TMemo;
    procedure btn1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form3: TForm3;

implementation

{$R *.dfm}

procedure TForm3.btn1Click(Sender: TObject);
var
  test : TTestJSON;
  JsonStr : String;
begin
  m1.Clear;
  test := TTestJSON.Create;
  try
    test.fVarThatWorksBeacuseItStartsWithF := 'WORKS';
    test.sVarThatFailsBecauseItStartsWithS := 'FAILS';
    JsonStr := TJson.ObjectToJsonString( test );
  finally
    test.Free;
  end;
  m1.Lines.Add(  '** JSONStr Value START **' + #13#10 + JsonStr + '** JSONStr Value END **' + #13#10 );

  test := TJson.JsonToObject<TTestJSON>(JsonStr);
  try
    m1.Lines.Add('** Obj loaded from JSON String Start **' + #13#10 + TJson.ObjectToJsonString( test ) + #13#10 + '** Obj loaded from JSON String End **');
  finally
    test.Free;
  end;
end;

end.

Answer 1

JSON Delphi 中的序列化基于字段，而不是属性。但是大多数 Delphi 类都有友好的属性和 F 前缀的字段。同时，Emb 似乎试图避免在生成的 JSON 中使用 F 前缀的名称。他们在序列化字段时首先从名称 "F" 中删除，并在从 JSON 读取时将其添加回去（以找到正确的字段）。似乎在 Delphi 中使用 JSON 序列化的唯一（安全）方法是保留所有带有前缀 "F" 的字段名称（对于您要序列化的字段）：

TTestJSON = class
protected
  FName: String;
public
  property Name: String read FName write FName;
end;

更新 2：正如 David 提到的，我们可以使用属性，然后我们有更好的控制：

uses
  REST.Json.Types, // without this unit we get warning: W1025 Unsupported language feature: 'custom attribute'
  REST.Json;

type
  // All fields of records are serialized, no control here.
  TRec = record
    RecStr: String;
  end;

  // By default all fields of class are serialized, but only F-prefixed serialized correctly.
  // We can use JSONMarshalled attribute to enable/disable serialization.
  // We can use JSonName attribute to serialize field with specific name in JSON.
  TTestJSON = class
    [JSONMarshalled(True)] [JSonName('RecField')]
    R: TRec;
  end;

procedure TForm28.FormCreate(Sender: TObject);
var
  Test: TTestJSON;
  JsonStr: string;
begin
  Test := TTestJSON.Create;
  try
    Test.R.RecStr := 'Some str';
    JsonStr := TJson.ObjectToJsonString( Test );
  finally
    FreeAndNil(Test);
  end;

  // JsonStr: {"RecField":["Some str"]}

  Test := TJson.JsonToObject<TTestJSON>(JsonStr);
  FreeAndNil(Test);
end;

Answer 2

这个库序列化字段。由于通常的做法是在字段前加上字母 F，因此设计人员希望从 JSON 中使用的名称中删除该字母。因此，他们决定将默认行为设为删除名称以 F 开头的字段中的第一个字母。坦率地说，这对我来说似乎很奇怪。

可以使用属性自定义此行为。例如：

[JSONMarshalled(False)]
FFoo: Integer; 

[JSONMarshalled(True)]
[JSONName('Blah')]
Bar: Integer;

据我所知，none 已正确记录。

Delphi Rest.JSON JsonToObject 仅适用于 f 变量

Delphi Rest.JSON JsonToObject only works with f variables

delphi

rest

json

vcl

delphi-xe8