创建表单时未调用 TPicture 属性的设置方法

Question

这是我的组件整体结构：

我的组件
- 属性类别：TCollection（属于 TCategory）
  - T类别
    - 属性图标：TPicture 读FIcon 写SetIcon;
    - 属性示例：整数读取 FExample 写入 SetExample;
    - （其他类别属性...）
- （其他属性...）

在 IDE 的 Object Inspector 中，我选择一张图片并成功序列化（我在表单视图中将其作为文本检查）。我在 SetIcon 方法上设置了一个断点，当我编译和运行应用程序时，它根本没有被调用。同时，SetExample 被正确调用。

TPicture属性有什么问题？

P.S: Set 方法在 IDE 时调用，但在运行时未调用。

这是代码的 MCVE：

unit MCVE;

interface

uses
  System.SysUtils, System.Classes, Vcl.Controls, Graphics, Dialogs;

type
  TMyCollectionItem = class(TCollectionItem)
  private
    FIcon: TPicture;
    procedure SetIcon(const Value: TPicture);
  public
    constructor Create(Collection: TCollection); override;
  published
    property Icon: TPicture read FIcon write SetIcon;
  end;

  TMyCollection = class(TCollection)
  end;

  TMCVE = class(TCustomControl)
  private
    FCollection: TMyCollection;
    procedure SetCollection(const Value: TMyCollection);
  public
    constructor Create(AOwner: TComponent); override;
  published
    property MyCollection: TMyCollection read FCollection write SetCollection;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Samples', [TMCVE]);
end;

{ TMyCollectionItem }

constructor TMyCollectionItem.Create(Collection: TCollection);
begin
  inherited;
  FIcon := TPicture.Create;
end;

procedure TMyCollectionItem.SetIcon(const Value: TPicture);
begin
  ShowMessage('SetIcon is called!');
  FIcon.Assign(Value);
end;

{ TMCVE }

constructor TMCVE.Create(AOwner: TComponent);
begin
  inherited;
  FCollection := TMyCollection.Create(TMyCollectionItem);
end;

procedure TMCVE.SetCollection(const Value: TMyCollection);
begin
  FCollection := Value;
end;

end.

Answer 1

对于 Integer、Boolean、Double 等简单类型，流式处理按照您描述的方式运行。流框架读取值，并调用属性 setter.

对于像 TPicture 这样更复杂的类型，情况并非如此。流框架无法调用属性 setter。为此，它需要掌握一个完整的 TPicture。它不知道如何先验地做到这一点。

那么会发生什么，流式框架调用属性的 getter 来获取组件的构造函数创建的 TPicture 实例。然后以 TPicture 的状态存储在 .dfm 文件中。

碰巧，TPicture 没有已发布的属性。图片数据保存到名为Data 的属性下的.dfm 文件中。那么，这是从哪里来的。答案在重写的 DefineProperties 方法中。代码如下所示：

procedure TPicture.DefineProperties(Filer: TFiler);

  function DoWrite: Boolean;
  begin
    // .... code removed for brevity
  end;

begin
  Filer.DefineBinaryProperty('Data', ReadData, WriteData, DoWrite);
end;

WriteData 和 ReadData 方法进行流式传输。

所以，回顾一下。您问为什么在图片属性中流式传输时没有调用 TPicture 属性的 setter。它不会被调用，因为您在构造函数中创建的图片对象在其属性中流动。

创建表单时未调用 TPicture 属性的设置方法

Set method of TPicture property doesn't get called when the form is created

delphi

components

vcl

delphi-xe7

创建表单时未调用 TPicture 属性 的设置方法

Set method of TPicture property doesn't get called when the form is created

delphi

components

vcl

delphi-xe7

创建表单时未调用 TPicture 属性的设置方法