使用 cmd 将文件日期附加到文件名

Question

您好，我想创建一个 bat 文件以使用 cmd 重命名文件。说一个朋友和我一起去度假。我们已经将所有图片放在一起，我现在想按顺序重命名所有图片。

假设我选择了以下图片：

mypicture_3435.jpg（文件日期 = 2015 年 1 月 1 日 10:00）
mypicture_3465.jpg（文件日期 = 2015 年 1 月 4 日 12:00）
myfriendspicture_2221.jpg（文件日期 = 2015 年 1 月 3 日 12:00）
myfriendspicture_2226.jpg（文件日期 = 2015 年 1 月 4 日 11:00）

我想获得以下输出：

ourvacation_01.jpg [mypicture_3435.jpg（文件日期 = 2015 年 1 月 1 日 10:00)]
ourvacation_02.jpg [myfriendspicture_2221.jpg（文件日期 = 03 2015 年 1 月 12:00)]
ourvacation_03.jpg [myfriendspicture_2226.jpg（文件日期 = 2015 年 1 月 4 日 11:00)]
ourvacation_04.jpg [mypicture_3465.jpg （文件日期 = 2015 年 1 月 4 日 12:00）]

使用 acdsee 等特定软件甚至 Windows' 图片浏览器都可以轻松做到这一点。但我想使用命令提示符来完成。（我在一所学校教数学，我想用这个作为编程示例）。

我尝试了以下脚本并且有效：

@echo off
setlocal EnableDelayedExpansion
set i=0
for %%a in (*.jpg) do (
    set /a i+=1
    ren "%%a" "!i!.new"
)
ren *.new *.jpg

但是它重命名了这样的文件：

myfriendspicture_2221.jpg 变为 1.jpg
myfriendspicture_2226.jpg 变为 2.jpg
mypicture_3435.jpg 变为 3.jpg
mypicture_3465.jpg 变为 4.jpg

所以问题是：

他们不按时间顺序排列。
如果我说 11 个项目，并按名称对它们进行排序，序列运行s 1, 10, 11, 2, 3, 4...

重命名前试过运行 dir /od，没用，顺序运行s按照文件名。

我找到的关于此问题的所有字符串都将当前日期和时间附加到文件名，而不是将文件日期和时间附加到它自己的名称。

我找不到在序列中添加前导 0 或 00 以使文件名和时间顺序匹配的方法。

非常感谢您的帮助。

Answer 1

I tried to run dir /od before I rename, but it didn't work, the sequence runs according to the file name.

你只是运行 dir /od 然后 for %%a in (*.jpg) 吗？您打算如何捕获 dir /od 的输出以使其有用，而不是仅仅将其转储到标准输出？

只要你想捕获命令的输出，就使用 for /f 循环。您应该像这样组合这两个命令：

for /f "delims=" %%I in ('dir /b /o:d *.jpg') do stuff.

下一期：零左填充文件名。我们可以假设您的假期照片不会超过 10,000 张吗？然后只需在生成的文件名前添加四个零，然后使用 right-most 4 characters 确定图片的基本名称。

@echo off
setlocal enabledelayedexpansion

set /a seq=10001
for /f "delims=" %%I in ('dir /b /o:d *.jpg') do (

    rem :: remove the "echo" when you are ready to rename
    echo ren "%%~I" "ourvacation_!seq:~-4!.jpg"

    set /a seq += 1
)

结果看起来有点像这样：

C:\Users\me\Desktop>test.bat
ren "avatar65929_2.jpg" "ourvacation_0001.jpg"
ren "IMG_20140621_190332.jpg" "ourvacation_0002.jpg"
ren "funny-Finding-Neverland-scene-Explorer.jpg" "ourvacation_0003.jpg"
ren "5DFPwMa.jpg" "ourvacation_0004.jpg"
ren "funny-root-math-equation.jpg" "ourvacation_0005.jpg"
ren "196889_145889312230730_1041953273_n.jpg" "ourvacation_0006.jpg"
ren "0001-cf72d77a-509ac348-b92c-fe8af7d2.jpg" "ourvacation_0007.jpg"
ren "IMG_20141230_191526.jpg" "ourvacation_0008.jpg"
ren "20150120_142150.jpg" "ourvacation_0009.jpg"
ren "20150120_145223.jpg" "ourvacation_0010.jpg"

使用 cmd 将文件日期附加到文件名

append file date to file name using cmd

windows

command-line

date

batch-file

file-rename