从 Ada 访问 c 常量

Question

我有一个头文件，其类型定义如下

#ifndef SETSIZE
   #define SETSIZE 32
#endif

typedef struct _set {
    unsigned  array[SETSIZE];
} set_t;

要使用相应的 C 函数，我需要在 Ada 中使用 set_t 类型。问题在于 SETSIZE 是一个可配置参数（默认值为 32）。如果我理解正确，我无法从 Ada 访问预处理器定义。是否可以向 c 文件添加一个常量并像这样在 Ada 中使用它：

#ifndef SETSIZE
   #define SETSIZE 32
#endif

const size_t test = SETSIZE;
// Alternative
enum { test2 = SETSIZE };

--Ada--
-- import test somehow
type set_array is array (0 .. test) of aliased Interfaces.C.unsigned;
type set_t is record
  array_field : aliased set_array;
end record;

或在 Ada 中正确使用此类型而无需对原始 C 代码进行太多更改的任何其他方式

Answer 1

在类似的情况下，我所做的是添加一个从 Ada 导入的函数：

size_t getsize(void) {
   return SETSIZE;
}

而在 Ada 方面：

function Getsize return Interfaces.C.size_t;
pragma Import(C, Getsize); -- From memory, this pragma is probably somewhat wrong

如果你不想重复调用这个函数，为了（我猜可以忽略不计）开销，你可以在函数定义之后：

Setsize : constant Interfaces.C.size_t := Getsize;
-- Or convert to any more convenient type at this point.

我猜你也可以对变量做同样的事情。

Answer 2

为什么不简单：

SetSize: constant Interfaces.C.Size_T;
pragma Import(
    Convention    => C,
    Entity        => SetSize,
    External_Name => "set_size" 
);

并且在您的 C 文件中：

const size_t set_size = SETSIZE;

使用 gnatmake 4.8.1 测试：

// File: set_def.c
#include <stdlib.h>

#ifndef SETSIZE
   #define SETSIZE 32
#endif

const size_t set_size = SETSIZE ;

typedef struct _set {
    unsigned  array[SETSIZE];
} set_t;

正在编译set_def.c:

Z:\> gcc -c set_def.c

-- File: main.adb
with Interfaces.C, Ada.Text_IO, Ada.Integer_Text_IO ;

procedure Main is

    use type Interfaces.C.Size_T ; -- To have access to the - operator

    SetSize: constant Interfaces.C.Size_T;

    pragma Import (
        Convention    => C,
        Entity        => SetSize,
        External_Name => "set_size" 
    );

    -- Note that you should go to SetSize - 1
    type Set_Array is array(0 .. SetSize - 1) of aliased Interfaces.C.Unsigned;
    type Set_T is
      record
        Array_Field: aliased Set_Array;
      end record;

    MySet: Set_T := (Array_Field => (1, 2, 3, others => 0)); 

begin
   Ada.Integer_Text_IO.Put (Integer(SetSize), 0); Ada.Text_IO.New_Line;
   Ada.Integer_Text_IO.Put (MySet.Array_Field'Length, 0); Ada.Text_IO.New_Line;
   for I in MySet.Array_Field'range loop
       Ada.Integer_Text_IO.Put (Integer(MySet.Array_Field(I)), 0);
       Ada.Text_IO.Put(' ');
   end loop;
end Main;

正在编译 main.adb 并与 set_def.o 链接：

Z:\> gnatmake main.adb -largs set_def.o
Z:\> main.exe
32
32
1 2 3 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0

从 Ada 访问 c 常量

Access c constant from Ada

c

ada