是否可以在 Erlang shell 中定义递归函数？

Question

我正在阅读 Programming Erlang，当我将这些输入 erlang REPL 时：

perms([]) -> [[]];
perms(L) -> [[H|T] || H <- L, T <- perms(L--[H])].
* 1: syntax error before: '->'

我知道我不能在 shell 中这样定义函数，所以我将其更改为：

2> Perms = fun([]) -> [[]];(L) -> [[H|T] || H <- L, T <- Perms(L--[H])] end.
* 1: variable 'Perms' is unbound

这是否意味着我无法在 shell 中定义递归函数？

Answer 1

因为 OTP 17.0 有命名的函数：

Funs can now be given names

README中有更多详细信息：

OTP-11537  Funs can now be a given a name. Thanks to to Richard O'Keefe
           for the idea (EEP37) and to Anthony Ramine for the
           implementation.

1> Perms = fun F([]) -> [[]];
               F(L) -> [[H|T] || H <- L, T <- F(L--[H])]
           end.    
#Fun<erl_eval.30.54118792>
2> Perms([a,b,c]).
[[a,b,c],[a,c,b],[b,a,c],[b,c,a],[c,a,b],[c,b,a]]

在旧版本中，你必须更聪明一点，但一旦你学会了：

1> Perms = fun(List) ->
               G = fun(_, []) -> [[]];
                      (F, L) -> [[H|T] || H <- L, T <- F(F, L--[H])]
                   end,
               G(G, List)
           end.    
#Fun<erl_eval.30.54118792>
2> Perms([a,b,c]).
[[a,b,c],[a,c,b],[b,a,c],[b,c,a],[c,a,b],[c,b,a]]

是否可以在 Erlang shell 中定义递归函数？

Is it possible to define a recursive function within Erlang shell?

erlang

erlang-shell