Delphi 字典释放

Question

我实施了以下 class：

type
  TUtilProcedure = procedure(var AJsonValue: TJSONObject);

  TCallback = class
  private
    FName: string;
    FProcedure: TUtilProcedure;
    FAnnotation: string;
  public
    constructor Create(AName: string; AProcedure: TUtilProcedure; AAnnotation: string); overload;
    constructor Create(ACallback: TCallback); overload;
    property Name: string read FName;
    property Proc: TUtilProcedure read FProcedure;
    property Annotation: string read FAnnotation;
 end;

然后我有一个全局变量：

procedures: TDictionary<string, TCallback>;

在 OnFormActivate 过程中，我初始化了 procedures 变量：

procedures := TDictionary<string, TCallback>.Create();
procedures.Add('something', TCallback.Create('sth', @proc, 'annotation')); 
// ....

然后在 OnFormClose 我释放它：

procedures.Clear;
procedures.Free;

我的代码会泄漏内存吗？如果是这样，释放 dictionary 的正确方法是什么？据我所知，迭代不是个好主意。

Answer 1

代码泄漏内存，因为 TDictionary 中包含的对象没有自动释放。

如果您需要将对象存储在字典中，采用TObjectDictionary是一种更好的方法。

如果要自动释放字典中包含的对象，请在创建集合实例时使用doOwnsValues标志。

当变量确实是全局的时（即在单元的interface部分的var下声明），它应该在单元本身的 initialization 和 finalization 部分中创建和销毁。

. . .
var
  procedures: TObjectDictionary<string, TCallback>;
. . .
initialization
  procedures:= TObjectDictionary<string, TCallback>.Create([doOwnsValues]);
finalization
  procedures.Free;

当您的变量属于表单 class 本身 时，您应该在表单的 OnCreate 事件中创建字典。

. . .
public
  procedures: TObjectDictionary<string, TCallback>;
. . .
procedure TForm1.FormCreate(Sender: TObject);
begin
  procedures:= TObjectDictionary<string, TCallback>.Create([doOwnsValues]);
end;

在表单的 OnDestroy 事件中释放字典：

procedure TForm1.FormDestroy(Sender: TObject);
begin
  procedures.Free;
end;

此外，如果您希望访问属于 class 的变量而不需要 class 本身的实例（这称为 静态变量 在许多编程语言中），您可以将字典声明为 class var 并可选择通过 class property 访问它；在这种情况下，最好在 class constructor 和 class destructor.

中创建和销毁集合

. . .
TMyClass = class
  private
    class constructor Create;
    class destructor Destoy;
  public
    class var procedures: TObjectDictionary<string, TCallback>;
end;
. . .
class constructor TMyClass.Create;
begin
  procedures := TObjectDictionary<string, TCallback>.Create([doOwnsValues]);
end;

class destructor TMyClass.Destoy;
begin
  procedures.Free;
end;

TCallback = class
  private
    FName: string;
    FProcedure: TUtilProcedure;
    FAnnotation: string;
  public
    constructor Create(AName: string; AProcedure: TUtilProcedure; AAnnotation: string); overload;
    constructor Create(ACallback: TCallback); overload;
    property Name: string read FName;
    property Proc: TUtilProcedure read FProcedure;
    property Annotation: string read FAnnotation;
end;

附带说明一下，TCallback class 不需要指定析构函数，因为它只拥有两个字符串和一个指向过程的指针。所以从 TObject 继承的默认析构函数就足够了。

Delphi 字典释放

Delphi dictionary freeing

delphi

dictionary

memory-leaks

tdictionary