输出中的空格

Question

我正在尝试将 xml 文档转换为另一个文档以获得逗号分隔的字符串。但是，当我转换时，我看到很多空格。

我不确定是什么原因造成的，我应该怎么做才能解决这个问题 -

XML 文件输入

    <File>
<row>
    <wid>WID0001</wid>
    <xtn>Leave Record</xtn>
    <status>In Process</status>
    <eid>E001</eid>
    <amt>5000</amt>
</row>


<row>
    <wid>WID0003</wid>
    <xtn>Leave Record</xtn>
    <status>In Process</status>
    <eid>E005</eid>
    <amt>3000</amt>
</row>

<row>
    <wid>WID0010</wid>
    <xtn>Leave Record</xtn>
    <status>In Process</status>
    <eid>E010</eid>
    <amt>7000</amt>
</row>


<row>
    <wid>WID0007</wid>
    <xtn>Leave Record</xtn>
    <status>In Process</status>
    <eid>E010</eid>
    <amt>0000</amt>
</row>

<row>
    <wid>WID0050</wid>
    <xtn>Leave Record</xtn>
    <status>In Process</status>
    <eid>E025</eid>
    <amt>750000</amt>
</row>

</File>

和 XSLT -

<?xml version='1.0'?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:this="http://abogusurl.com">

    <xsl:output indent="yes" method="xml" />

        <xsl:template match="/File">
            <widlist>
                <xsl:apply-templates />
            </widlist>
        </xsl:template>

       <xsl:template match="row">
            <xsl:value-of select="wid" /> 
            <xsl:value-of select="','" />
    </xsl:template>

</xsl:stylesheet>

输出

<?xml version="1.0"?>
<widlist x xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:this="http://abogusurl.com">
WID0001,


WID0003,

WID0010,


WID0007,

WID0050,

</widlist>

如何消除空格？

Answer 1

所以我认为添加 <xsl:strip-space elements="*"/> 会达到你想要的效果。

Answer 2

您的 XML 在 row 个元素之间有 text() 个节点。 built-in template rules 将它们保留在输出中。

您可以通过添加与那些纯空白文本节点匹配的空模板来抑制那些 text() 节点：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output indent="yes" method="xml"/>

    <xsl:template match="/File">
        <widlist>
            <xsl:apply-templates/>
        </widlist>
    </xsl:template>

    <xsl:template match="row">
        <xsl:value-of select="wid"/>
        <xsl:value-of select="','"/>
    </xsl:template>

    <!--suppress whitespace-only text nodes-->
    <xsl:template match="text()[not(normalize-space())]"/>

</xsl:stylesheet>

您也可以让空模板匹配 File/text():

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output indent="yes" method="xml"/>

    <xsl:template match="/File">
        <widlist>
            <xsl:apply-templates/>
        </widlist>
    </xsl:template>

    <xsl:template match="row">
        <xsl:value-of select="wid"/>
        <xsl:value-of select="','"/>
    </xsl:template>

    <!--suppress (whitespace) text nodes that are children of File-->
    <xsl:template match="File/text()"/>

</xsl:stylesheet>

或者您可以通过仅将模板应用于文件模板中的 row 元素来排除那些 File/text() 节点：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output indent="yes" method="xml"/>

    <xsl:template match="/File">
        <widlist>
            <xsl:apply-templates select="row"/>
        </widlist>
    </xsl:template>

    <xsl:template match="row">
        <xsl:value-of select="wid"/>
        <xsl:value-of select="','"/>
    </xsl:template>

</xsl:stylesheet>

所有这些解决方案都删除了额外的空格和换行符并产生以下输出：

<widlist>WID0001,WID0003,WID0010,WID0007,WID0050,</widlist>

此实现当前正在 widlist 中生成尾随逗号。

您可以通过更改行模板来解决此问题：

<xsl:template match="row">
    <xsl:value-of select="wid"/>
    <xsl:if test="position() != last()">
        <xsl:text>,</xsl:text>
    </xsl:if>
</xsl:template>

如果您使用的是 XSLT 2.0 并希望生成逗号分隔列表，您可以将样式表缩短为：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output indent="yes" method="xml"/>

    <xsl:template match="/File">
        <widlist>
            <xsl:value-of select="row/wid" separator=","/>
        </widlist>
    </xsl:template>

</xsl:stylesheet>

输出中的空格

Spaces in output

xslt

whitespace

xslt-2.0

removing-whitespace

XML 文件输入

输出