添加百分比 % 到 proc 制表报告

Question

我有一个过程列表代码如下：

  proc tabulate data=want;
class TERM CAMPUS GENDER ;
  var count ;
 table  GENDER ALL, (CAMPUS all)*TERM*(count='#Enrl '*f=best8.*sum=' ' count=''*colpctsum='% Tot Enrl ' ) / rts=20;
run;

我的结果如下

                               campus
                             East Campus
                               Term
           Spring 2014               Spring 2015             Dfference
        #Enrl     %Tot_Enrl         #Enrl   %ToT_Enrl      #Enrl   %Tot_Enrl
Gender   
Female   8462      52.86             8429    52.36          -33       -37.08
Male     7478      46.71             7608    47.26          130       146.07
None     68        0.42              60      0.37            -8        -8.89
All      16008      100.00           16907    100.00        89          100

我需要在“%Tot_Enrl”变量中添加 % 符号。我还可以删除校区和学期标题吗？我有 'campus' 头衔和 'east campus' 头衔。所以我需要删除 'Campus' 和 'Term'。那可能吗？

Answer 1

您需要更多 =' ' 才能摆脱 Campus 和 Term。要获得百分号，您需要一种格式； SAS shows you how here.

data want;
  format term . campus .;
  input term $ & campus $ & gender $ count;
  datalines;
Spring 2014  East Campus  Female 8462
Spring 2014  East Campus  Male 7478
Spring 2014  East Campus  None 68
Spring 2015  East Campus  Female 8429
Spring 2015  East Campus  Male 7608
Spring 2015  East Campus  None 60
Difference  East Campus  Female -33
Difference  East Campus  Male 130
Difference  East Campus  None -8
;;;;
run;



proc format;                           
   picture mypct(round) low-high='000,009.90%' (mult=100);   
run; 


proc tabulate data=want;
  class TERM CAMPUS GENDER ;
  var count ;
  table  GENDER ALL, (CAMPUS=' ' all)*TERM=' '*(count='#Enrl '*f=best8.*sum=' ' count=''*colpctsum='% Tot Enrl '*f=mypct. ) / rts=20;
run;

排序结果是错误的，我猜你对其中的一些有一个格式化的数字，但它理解了这个想法。

添加百分比 % 到 proc 制表报告

Adding percent % to the proc tabulate report

sas

enterprise-guide