替换 JENA Triplestore 中的域

Question

我想更换存储在基于耶拿的三重存储中的所有主题的服务器。

我这样试过了，但是服务器没有被替换...

DELETE { ?s ?p ?o }
INSERT { ?s1 ?p ?o }
WHERE { 
    { SELECT (uri(concat('http://localhost:8080/', SUBSTR(str(?s),22))) AS ?s1) 
        { 
          ?s ?p ?o . 
          FILTER regex(str(?s), '^https://somedomain.org/')
        }
     }
}

当我只运行以下查询

SELECT (uri(concat('http://localhost:8080/', SUBSTR(str(?s),22)) ) AS ?s1) ?s 
{ 
  ?s ?p ?o . 
  FILTER regex(str(?s), '^https://somedomain.org/')
}

'?s' 和 '?s1' 确实具有正确的值。

DELETE/INSERT 块中似乎没有“?s”和“?s1”。我的更新查询有什么问题？

Answer 1

您的问题是您在更新中使用了子查询，并且您只从子查询中投影 ?s1。

这意味着 ?s、?p 和 ?o 在子查询之外不可见。因此，当 DELETE 和 INSERT 模板尝试构建三元组以删除和插入时，它们构建的所有三元组都是无效的（因为并非所有变量都是可见的），因此没有任何变化。

要解决此问题，您应该投影所有相关变量：

DELETE { ?s ?p ?o }
INSERT { ?s1 ?p ?o }
WHERE 
{ 
  {
    SELECT ?s ?p ?o (uri(concat('http://localhost:8080/', SUBSTR(str(?s),22))) AS ?s1) 
    { 
      ?s ?p ?o . 
      FILTER regex(str(?s), '^https://somedomain.org/')
    }
  }
}

或遵循评论中的 Joshua Taylor's 建议。这实际上更好，因为它简化了整个查询：

DELETE { ?s ?p ?o }
INSERT { ?s1 ?p ?o }
WHERE 
{ 
  ?s ?p ?o . 
  FILTER regex(str(?s), '^https://somedomain.org/')
  BIND(uri(concat('http://localhost:8080/', SUBSTR(str(?s),22))) AS ?s1)
}

替换 JENA Triplestore 中的域

Replacing domain in JENA Triplestore

sparql

apache-jena