折叠在绳子上

Question

我想折叠一个字符串，以便用 "k" 替换任何出现的以 @ 开头的零。所以 "a.@0.1.2.0" 变成了 "a.@k.1.2.0"。我怎么做？到目前为止我的尝试是

test = foldl(\x acc-> if((last acc) == "@" && x == "0" then acc ++ "k" else acc ++ x)) "" "a.@0.1.2.0"

然而，它不起作用。 Foldl 期待字符串列表，而我提供的只是一个字符串。我该如何克服？

Answer 1

采纳 chi 的建议，

rep "" = ""
rep ('@' : '0' : xs) = "@k" ++ rep xs
rep (x : xs) = x : rep xs

如果我们想变得更漂亮，

rep = snd . mapAccumL go False
  where
    go True '0' = (False, 'k')
    go _ '@' = (True, '@')
    go _ x = (False, x)

甚至

rep = snd . mapAccumL go 'x'
  where
    go '@' '0' = ('0', 'k')
    go _ y = (y, y)

要将 foldr 与第二种方法一起使用（只是因为它更短；第一种方法也可以正常工作，并且允许泛化），

rep xs = foldr go (const "") xs 'x'
  where
    go '0' r '@' = 'k' : r '0'
    go x r _ = x : r x

要使用zipWith（更难概括）：

rep xs = zipWith go ('x' : xs) xs where
  go '@' '0' = 'k'
  go _ x = x

Answer 2

正如其他人评论的那样，foldl 不适合这项任务。但是，使用 difference list 的想法，您仍然可以使用 foldl:

高效地 执行此操作

repl :: String -> String
repl a = foldl loop id a ""
    where
    loop :: (String -> String) -> Char -> (String -> String)
    loop f '@' ('0':rest) = f ('@':'k':rest)
    loop f x xs = f (x:xs)

只是为了演示的目的以及问题已经要求 foldl 解决方案的事实。（并不是说我会推荐这样做）。

折叠在绳子上

Foldl on string

haskell

fold