如何列出具有特定原子的所有谓词？

Question

另一种提问方式是：

如何列出一个原子的所有属性？

例如：

movie(agora).
director(agora, 'Alejandro Amenabar')
duration(agora, '2h').

所以，我想接收所有具有 agora 参数的谓词。在这种情况下，它将是：movie、director、duration，以及其他参数 ('Alejandro Amenabar', '2h').

我找到了：, and this 个问题，但我不太理解。

如果 PersonInvited 不喜欢这部电影的某些方面，我想在“变量答案”中使用 false 值。

我的查询将是：

answer(Answer, PersonInvited, PersonWhoMadeInvitation, Movie)

答：不喜欢这个导演

answer(false, PersonInvited, PersonWhoMadeInvitation, Movie):-
    director(Movie, DirectorName),not(like(PersonInvited,DirectorName)).

例如，任何属性类型都会发生同样的事情。

回答：我不喜欢这个类型

answer(false, PersonInvited, PersonWhoMadeInvitation, Movie):-
    genre(Movie, Genre), not(like(PersonInvited,Genre)).

所以，我想概括这种情况，而不是重复写每个对象的每个特征。

Answer 1

使用reading lines into lists with prolog

您所有的谓词都在一个文件中 'my_file.pl'。

例如my_file.pl 包含：

movie(agora).
director(agora, 'Alejandro Amenabar').
duration(agora, '2h').

您可以使用：

getLines(File,L):-
 setup_call_cleanup(
 open(File, read, In),
 readData(In, L),
 close(In)
 ).

readData(In, L):-
  read_term(In, H, []),
  (   H == end_of_file
  ->  L = []
  ;   L = [H|T],
      readData(In,T)
  ).


pred_arg_file(Pred,Argue,File):-
  getLines(File,L),
  member(M,L),
  M=..List,
  member(Argue,List),
  List=[Pred|_].

那你可以查询：

 ?-pred_arg_file(Pred,agora,'my_file.pl').
 Pred = movie ;
 Pred = director ;
 Pred = duration ;
 false

或

?- findall(Pred,pred_arg_file(Pred,agora,'my_file.pl'),Preds).
Preds = [movie,director,duration].

如果你想要 return 属性，return 整个 List 而不仅仅是头部。

pred_arg_file(List,Argue,File):-
  getLines(File,L),
  member(M,L),
  M=..List,
  member(Argue,List).

Answer 2

这是我的尝试，使用 SWI-Prolog

?- current_predicate(so:F/N), N>0, length(As,N), Head =.. [F|As], clause(so:Head,Body), As=[A|_], A==agora.

注意我编码成一个模块叫so的事实，所以我用模块名限定相关调用。此类内置函数 (clause/2 and current_predicate/1) 符合 ISO，而模块（在 SWI-prolog 中）则不符合。所以我不确定可移植性等...

clause/2它是一个内置函数，可以轻松编写metainterprets。请参阅 link 以获得对这个 Prolog 历史 'point of strength' 的精彩介绍。

最后 2 次调用（我的意思是，As=[A|_], A==agora）避免匹配以变量作为第一个参数的子句。

Answer 3

如果我正确理解了你的问题，我建议如下：

如果你改变你的架构或者遵循这个想法你可以制作一个模拟相同事物的方法。

class(movie, agora).
property(director, agora, 'Alejandro Amenabar').
property(duration, agora, '2h').

如果你想要agora的类型，查询将是：

class(Type, agora)

如果你想要agora的所有属性，那就是：

property( PropertyName, agora, Value).

Answer 4

根据我的理解，你应该改变你的数据表示，这样你就可以查询 relations.As 其他答案已经指出，所以使用三元组，你可以轻松地编写代码来将你的所有关系变成这种形式一关。然后你需要弄清楚存储喜欢或不喜欢的最佳方式是什么。这将影响否定的工作方式。在这个例子中：

relation(starwars,is,movie).
relation(lucas, directs,starwars).
relation(agora, is,movie).
relation('Alejandro Amenabar', directs, agora).
relation(agora, duration, '2h').

like(ma,'Alejandro Amenabar').
like(ma,movie).
like(ma,'2h').

ma_does_not_want_to_go(Film):-
  relation(Film,is,movie),
  relation(Film,_,Test), \+like(ma,Test).
ma_does_not_want_to_go(Film):-
  relation(Film,is,movie),
  relation(Test,_,Film), \+like(ma,Test).

ma_wants_to_go(Film):-
  relation(Film,is,movie),
  \+ma_does_not_want_to_go(Film).

sa_invites_ma(Film,true):-
  ma_wants_to_go(Film).

sa_invites_ma(Film,false):-
  ma_does_not_want_to_go(Film).

Answer 5

使用 Logtalk 和 GNU Prolog 作为后端编译器的解决方案草案：

% a movie protocol
:- protocol(movie).

    :- public([
        director/1,
        duration/1,
        genre/1
    ]).

:- end_protocol.


% a real movie
:- object('Agora',
    implements(movie)).

    director('Alejandro Amenabar').
    duration(120).
    genre(drama).

:- end_object.


% another real movie
:- object('The Terminator',
    implements(movie)).

    director('James Cameron').
    duration(112).
    genre(syfy).

:- end_object.


% a prototype person
:- object(person).

    :- public([
        likes_director/1,
        likes_genre/1
    ]).

    :- public(likes/1).
    likes(Movie) :-
        conforms_to_protocol(Movie, movie),
        (   Movie::genre(Genre),
            ::likes_genre(Genre) ->
            true
        ;   Movie::director(Director),
            ::likes_director(Director) ->
            true
        ;   fail
        ).

:- end_object.


% a real person
:- object(mauricio,
    extends(person)).

    likes_director('Ridlye Scott').

    likes_genre(drama).
    likes_genre(syfy).

:- end_object.

一些示例查询：

$ gplgt
...

| ?- {movies}.
...

(5 ms) yes
| ?- mauricio::likes('Agora').

true ? 

yes
| ?- mauricio::likes(Movie).  

Movie = 'Agora' ? ;

Movie = 'The Terminator' ? ;

no

| ?- 'The Terminator'::director(Director).

Director = 'James Cameron'

yes

可以通过多种方式改进代码，但它应该足以让您清楚地了解如何评估此解决方案。

Answer 6

我找到了两个解决方案，从我的角度来看，第二个更清晰，但它们是不同的。

参数:

PredName:谓词名称。
Arity: 谓词的 Arity。
ParamValue: 如果我想按某一特定参数过滤。
PosParam: 参数在谓词中的位置。
ListParam:所有可能的values参数的值（必须一直是Variable）。

解决方案 1:

filter_predicate(PredName, Arity, ParamValue,PosParam, ListParam):-
    current_predicate(PredName/Arity),
    Arity >= PosParam,
    nth(PosParam, ListParam, ParamValue),
    append([PredName], ListParam, PredList),
    GlobalArity is Arity + 1,
    length(PredList, GlobalArity),
    Predicate =.. PredList,
    Predicate.

查询

filter_predicate(PredName, Arity, agora, 1, Pm).

输出

Arity = 2                                                                              
Pm = [agora,'Alejandro Amenabar']
PredName = director ? 

yes

解决方案2:

filter_predicate(PredName, Arity, ParamList):-
    current_predicate(PredName/Arity),
    append([PredName], ParamList, PredList), 
    GlobalArity is Arity + 1,
    length(PredList, GlobalArity),
    Predicate =.. PredList,
    Predicate.

查询 1:

filter_predicate(PredName, Arity, [agora, X]).

输出

Arity = 2
PredName = director
X = 'Alejandro Amenabar' ?

查询 2:

filter_predicate(PredName, Arity, [X, 'Alejandro Amenabar']).

输出

Arity = 2
PredName = director
X = agora ?

如何列出具有特定原子的所有谓词？

How to list all predicates that has an specific atom?

reflection

predicate

prolog

gnu-prolog