过程指针数组的自动初始化

Question

有什么方法可以自动初始化过程指针常量数组吗？

我有一堆例程，必须根据整数变量的值来调用它们。我不想使用 select case 语句，而是使用下面给出的过程指针。但是，如果我可以跳过过程指针数组的显式初始化，而只是将其定义为包装过程指针的常量数组，那就太好了。下面的代码演示了我找到的解决方案，注释行表示目标，我想实现：

module testmod
  implicit none

  abstract interface
    subroutine subInterface()
    end subroutine subInterface
  end interface

  type :: SubPtr
    procedure(subInterface), nopass, pointer :: ptr
  end type SubPtr

  ! Would be nice to use something like this:
  !type(SubPtr), parameter :: subs(2) = [ SubPtr(sub1), SubPtr(sub2) ]

contains

  subroutine sub1()
    print *, "SUB1"
  end subroutine sub1

  subroutine sub2()
    print *, "SUB2"
  end subroutine sub2

end module testmod


program test
  use testmod
  implicit none

  type(SubPtr) :: subs(2)
  integer :: ii

  ! Would be nice to get rid of those two initialization lines
  subs(1) = SubPtr(sub1)  
  subs(2) = SubPtr(sub2)

  ! Testing procedure pointer array
  do ii = 1, 2
    call subs(ii)%ptr()
  end do

end program test

Answer 1

我认为这（您注释掉的 "Would be nice..." 类型声明语句）只需要（有效的）Fortran 2008 支持。为了在常量表达式中有效，结构构造函数中对应于指针组件的组件可以是初始化目标 (7.1.12p1 3b)。对于过程指针组件，初始化目标是 initial-proc-target，它允许（除其他外）非元素模块过程，这就是 sub1 和sub2两者都是。

过程指针数组的自动初始化

Automatic initialization of procedure pointer arrays

fortran

fortran2003

fortran2008