将 DBLookupCombobox 添加到 Delphi DBGrid

Question

我想将 DBLookupComboboxes 添加到 DBGrid 中的某些列。 About.com 上有一篇很好的文章介绍了如何做到这一点 here。问题是 table 有很多列，如果您从 DBLookupCombobox 中的一列 select 然后尝试向左滚动，组合框也会向左移动，如包含的图像所示。如何更改 About.com 代码以防止这种行为？网络搜索显示另外两个人抱怨完全相同的问题，但没有解决方案。请注意，我想使用 DBLookupCombobox 来显示名称但输入 ID，因此使用简单的选择列表是行不通的。

procedure TForm1.DBGrid1ColExit(Sender: TObject);
begin
  if DBGrid1.SelectedField.FieldName = DBLookupComboBox1.DataField then
    DBLookupComboBox1.Visible := False
end;

procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
begin
  if (gdFocused in State) then
  begin
    if (Column.Field.FieldName = DBLookupComboBox1.DataField) then
    with DBLookupComboBox1 do
    begin
      Left := Rect.Left + DBGrid1.Left + 2;
      Top := Rect.Top + DBGrid1.Top + 2;
      Width := Rect.Right - Rect.Left;
      Width := Rect.Right - Rect.Left;
      Height := Rect.Bottom - Rect.Top;

      Visible := True;
    end;
  end
end;

procedure TForm1.DBGrid1KeyPress(Sender: TObject; var Key: Char);
begin
  if (key = Chr(9)) then Exit;

  if (DBGrid1.SelectedField.FieldName = DBLookupComboBox1.DataField) then
  begin
    DBLookupComboBox1.SetFocus;
    SendMessage(DBLookupComboBox1.Handle, WM_Char, word(Key), 0);
  end
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
 with DBLookupComboBox1 do
 begin
   DataSource := DataSource1; // -> AdoTable1 -> DBGrid1
   ListSource := DataSource2;
   DataField   := 'resource_id'; // from AdoTable1 - displayed in the DBGrid
   KeyField  := 'id';
   ListField := 'resource_name; id';

   Visible    := False;
 end;

 DataSource2.DataSet := AdoQuery1;

 AdoQuery1.Connection := AdoConnection1;
 AdoQuery1.SQL.Text := 'SELECT id,resource_name FROM resources';
 AdoQuery1.Open;
end;

Answer 1

这是一个使用 François.

巧妙技巧的解决方案

type
    // Hack to redeclare your TDBGrid here without the the form designer going mad
    TDBGrid = class(DBGrids.TDBGrid)
      procedure WMHScroll(var Msg: TWMHScroll); message WM_HSCROLL;
    end;

  TForm1 = class(TForm)
[...]
procedure TDBGrid.WMHScroll(var Msg: TWMHScroll);
begin
  if Form1.DBGrid1.SelectedField.FieldName = Form1.DBLookupComboBox1.DataField then begin
    case Msg.ScrollCode of
      SB_LEFT,SB_LINELEFT,SB_PAGELEFT: begin
        Form1.DBGrid1.SelectedIndex := Form1.DBGrid1.SelectedIndex-1;
        Form1.DBLookupComboBox1.Visible := False;
      end;
      SB_RIGHT,SB_LINERIGHT,SB_PAGERIGHT: begin
        Form1.DBGrid1.SelectedIndex := Form1.DBGrid1.SelectedIndex+1;
        Form1.DBLookupComboBox1.Visible := False;
      end;
    end;
  end;
  inherited; // to keep the expected behavior
end;

将 DBLookupCombobox 添加到 Delphi DBGrid

Add DBLookupCombobox to Delphi DBGrid

delphi

dbgrid