python 脚本在批处理文件中弄乱了 %time%

Question

我正在使用一个批处理文件，我会定期在其中写入时间以进行性能监控。这很好用，但最近我在该批处理文件中调用了一个 Python 脚本，时间测量似乎不再起作用：
我的批处理文件如下所示：

echo [%TIME%] -- task 1
<perform task 1>
echo [%TIME%] -- task 2
<perform task 2>
echo [%TIME%] -- finished

，结果如下：

[14:51:32.97] -- task 1
[14:51:34.32] -- task 2
[14:51:39.07] -- finished

现在我已经用 Python 脚本替换了（这至少需要几分钟），但是我的 %TIME% 变量似乎不再更新了：

echo [%TIME%] -- task 1
<perform task 1>
echo [%TIME%] -- task 2
python task2.py
echo [%TIME%] -- finished

给出以下结果：

[14:51:40.02] -- task 1
[14:51:44.32] -- task 2
[14:51:44.32] -- finished

有人知道可能导致此问题的原因以及解决方法吗？
供您参考，我正在使用虚拟 Windows 7 系统，我的 Python 安装版本是 3.5.0.

Answer 1

我相信这个问题不是 'python-related'。例如脚本

@echo off

echo [%TIME%] ---
echo [%TIME%] ping1
ping 8.8.8.8 >nul
echo [%TIME%] ping1 done

if not exist 123 (
echo [%TIME%] ping2
ping 8.8.8.8 >nul
echo [%TIME%] ping2 done
)

echo [%TIME%] ping3
ping 8.8.8.8 >nul
echo [%TIME%] ping3 done
echo [%TIME%] ---

会输出

[20:33:32,00] ---
[20:33:32,00] ping1
[20:33:35,04] ping1 done
[20:33:35,04] ping2
[20:33:35,04] ping2 done
[20:33:38,12] ping3
[20:33:41,16] ping3 done
[20:33:41,16] ---

如您所见，ping2 和 ping2 done 具有相同的时间戳。当使用括号 ( ) 时，CMD shell 将扩展 [读取] 代码块开头的所有变量并使用这些值，即使变量值在代码块内发生更改.

所以在这种情况下，解决方案是

if not exist 123 (
call echo [%%TIME%%] ping2
ping 8.8.8.8 >nul
call echo [%%TIME%%] ping2 done
)

或

@echo off
Setlocal EnableDelayedExpansion
...
if not exist 123 (
echo [!TIME!] ping2
ping 8.8.8.8 >nul
echo [!TIME!] ping2 done
)

输出为

[20:45:28,45] ---
[20:45:28,45] ping1
[20:45:31,49] ping1 done
[20:45:31,49] ping2
[20:45:34,53] ping2 done
[20:45:34,54] ping3
[20:45:37,59] ping3 done
[20:45:37,59] ---

python 脚本在批处理文件中弄乱了 %time%

python script messes up %time% in batchfile

python

batch-file

windows-7