在 Qt 多媒体中拍摄视频快照

Question

是否可以在 Qt Multimedia 中拍摄视频快照？怎么样？

Answer 1

这取决于平台，但您可能会做的是使用 QMediaPlayer, set a subclassed video surface via setVideoOutput, and get the frame data from the QVideoFrame passed in the present 方法。如果这些不在 CPU 内存中，您将不得不处理帧格式并进行映射。

但是，根据您的需要，我会使用 ffmpeg/libav 从特定位置获取帧。

Answer 2

试试这个（此处的文档：http://doc.qt.io/qt-5/qml-qtquick-item.html#grabToImage-method）

import QtQuick 2.5
import QtQuick.Window 2.2
import QtQuick.Controls 1.4
import QtQuick.Layouts 1.1
import QtMultimedia 5.0

Window {
    id: mainWindow
    visible: true
    width: 480
    height: 800

    MediaPlayer {    
        id: player
        source: "file:///location/of/some/video.mp4"
        autoPlay: false            
    }

    ColumnLayout {
        anchors.fill: parent
        VideoOutput {
            id: output
            source: player
            Layout.fillHeight: true
            Layout.fillWidth: true                
        }

        Row {
            id: buttonsRow
            height: 100
            spacing: 20
            anchors.horizontalCenter: parent.horizontalCenter
            Layout.margins: 10                

            Button {
                id: playPauseButton
                text: player.playbackState === MediaPlayer.PlayingState ? "Pause" : "Play"
                onClicked: {
                    var playing = player.playbackState === MediaPlayer.PlayingState;
                    playing ? player.pause() : player.play();
                }
            }                
            Button {
                text: "Snapshot"
                onClicked: {
                    output.grabToImage(function(image) {
                        console.log("Called...", arguments)
                        image.saveToFile("screen.png"); // save happens here
                    });
                }
            }
        }
    }
}

在 Qt 多媒体中拍摄视频快照

Take snapshot of video in Qt Multimedia

video

qt

snapshot

qmediaplayer

qtmultimedia