如何遍历变量名的一部分？

Question

我需要使用局部宏来遍历 Stata 中的部分变量名。

这是我尝试做的事情：

local phth mep mibp mbp
tab lod_`phth'_BL

Stata 无法识别整个变量名。

variable lod_mep not found
r(111);

如果我删除 `phth' 后的下划线，它仍然无法识别宏名称后的任何内容。

我想避免使用复杂的 foreach 循环。

有什么方法可以只使用简单的宏来完成吗？谢谢！

Answer 1

您的要求有点混乱。首先，这正是循环的目的，其次，Stata 中的循环（在 "introductory level"）非常简单。下面的例子有点荒谬（考虑到结构，有更简单的方法来解决这个问题），但应该传达基本思想。

// set up a similar variable name structure
sysuse auto , clear
rename (price mpg weight length) /// 
       (pref_base1_suff pref_base2_suff pref_base3_suff pref_base4_suff)

// define a local macro to hold the elements to loop over
local varbases = "base1 base2 base3 base4"

// refer to the items of the local macro in a loop
foreach b of local varbases {
    summ pref_`b'_suff
}

有关 foreach 的语法，请参阅 help foreach。特别要注意，由于 Stata 的 varlist 结构（请参阅 help varlist），甚至可能不需要上述结构。例如，继续上面的代码：

foreach v of varlist pref_base?_suff {
    summ `v'
}

通配符?代替一个字符。 * 可用于获得更大的灵活性。但是，如果使用 varlist 允许的模式匹配无法轻松识别您的变量，那么第一个示例中的循环就足够简单了——四行非常短的代码。

后记

经过进一步思考（有时问题的结构锚定了某种方法，当替代方法更直接时），在帮助文件中搜索有关制表命令的信息（help tabulate）将指导您以下语法：tab1 varlist [if] [in] [weight] [, tab1_options]

鉴于上面关于 varlists 的使用的讨论，您可以简单地编写代码

tab1 lod_m*_BL

当然，假设没有其他变量与您不想要报告频率table的模式相匹配。或者，

tab1 lod_mep_BL lod_mibp_BL lod_mbp_BL

虽然没有使用任何类型的通配符或宏替换，但不会太长并且可以解决问题。

如何遍历变量名的一部分？

How do I loop over part of a variable name?

stata

stata-macros

后记