命令后 Tck、vwait 和事件循环

Question

我的 Tk 应用程序有很多 "wait" windows 或功能暂停，让其他后台命令有时间完成它们的工作。问题是在函数中使用 "after 5000" 会禁用应用程序中的所有按钮。我找到了很多信息，最有帮助的是 http://wiki.tcl.tk/808。第一个教训是没有脚本的 "after" 不会处理事件循环，第二个是 vwaits 是嵌套的。

因此，我使用以下简单的 "pause" 函数代替 "after"：

proc pause {ms {waitvar WAITVAR}} {
   global $waitvar
   after $ms "set $waitvar 1"
   puts "waiting $ms for $waitvar"
   vwait $waitvar
   puts "pause $ms returned"
}

button .b -text PressMe -command {pause 5000 but[incr i]}; # everyone waits on this
pack .b
after 0 {pause 1000 var1}; pause 3000 var2; # works as expected
after 0 {pause 3000 var3}; pause 1000 var4; # both return after 3 secs

我的按钮总是有响应，但如果按下，所有其他 vwait 至少会再等待 5 秒钟。并且在 5 秒内第二次按下也会延迟第一次按下。了解 vwaits 是嵌套的，现在这是预期的并且不是真正的问题。

这个解决方案似乎太简单了，所以我想就我可能没有遇到的问题征求意见。

Answer 1

您列出了主要问题，即 vwait 调用将愉快地嵌套在另一个 vwait 调用中。（它们是使用对事件循环引擎的递归调用来实现的，所以这是可以预料的。）当你得到最终嵌套在自身内部的东西时，这可能是一个特殊的问题；你可以很容易地以这种方式炸毁堆栈。解决此问题的传统方法是小心联锁，例如在处理 vwait 时禁用调用此特定回调的按钮；这也提供了一种很好的方式来向用户表明您很忙。

另一种方法（您可能仍会在禁用按钮时使用）是分解代码，而不是：

proc callback {} {
    puts "do some stuff 1"
    pause 5000
    puts "do some stuff 2"
}

你改为：

proc callback {} {
    puts "do some stuff 1"
    after 5000 callback2
}
proc callback2 {} {
    puts "do some stuff 2"
}

这可以让您避免 vwait 本身。它被称为连续传递风格编程，它在高质量的 Tcl 代码中很常见。虽然它确实有点棘手。考虑这个循环版本：

proc callback {} {
    for {set i 1} {$i <= 5} {incr i} {
        puts "This is iteration $i"
        pause 1000
    }
    puts "all done"
}

在连续传递风格中，你会做这样的事情：

proc callback {{i 1}} {
    if {$i <= 5} {
        puts "This is iteration $i"
        after 1000 [list callback [incr i]]
    } else {
        puts "all done"
    }
}

您拥有的本地状态越多，转换代码就越棘手！

使用 Tcl/Tk 8.6，您获得了一些额外的技巧。

首先，您可以使用 coroutine 来简化棘手的连续传递内容。

proc callback {} {
    coroutine c[incr ::coroutines] apply {{} {
        for {set i 1} {$i <= 5} {incr i} {
            puts "This is iteration $i"
            after 1000 [info coroutine]
            yield
        }
        puts "all done"
    }}
}

这有点长，但是随着状态的大小和复杂性的增加，更容易。

另一个新的 8.6 工具是 tk busy 命令，它可以用来制作方便的模态对话框，在某些操作发生时您无法与之交互（通过隐藏 [=47= 的巧妙技巧） ]).仍然由您的代码来确保告知用户事情很忙，再次通过将事情标记为禁用等，但是 tk busy 可以使其更容易实现（并且可以帮助避免小技巧的嵌套grab).

的问题

命令后 Tck、vwait 和事件循环

Tck after command, vwait, and the event loop

event-handling

tcl

event-loop