如何在不先加载图像的情况下使用扫描线绘制？

Question

我正在尝试执行以下操作：

bmp := TBitmap.Create;
bmp.Width := FWidth;
bmp.Height := FHeight;
for y := 0 to FHeight - 1 do
begin
   sl := bmp.ScanLine[y];
   for x := 0 to FWidth - 1 do
   begin
      //draw to the scanline, one pixel at a time
   end;
end;
//display the image
bmp.Free;

不幸的是，我最终得到的是一个完全白色的图像，除了底线，它被适当地着色了。一些调试表明，每次我访问 ScanLine 属性，它都会调用 TBitmap.FreeImage，然后进入 if (FHandle <> 0) and (FHandle <> FDIBHandle) then 块，这会重置整个图像，所以只有实际更改最后一行。

到目前为止，在我使用 TBitmap.ScanLine 看到的每个演示中，它们都是从加载图像开始的。（显然，这正确地设置了各种句柄，这样就不会发生这种情况？）但我并不是要加载图像并对其进行处理；我正在尝试从相机捕获图像数据。

如何设置位图，以便在不先加载图像的情况下绘制扫描线？

Answer 1

您应该在开始绘制之前明确设置 PixelFormat。例如，

procedure TForm1.FormPaint(Sender: TObject);
var
  bm: TBitmap;
  y: Integer;
  sl: PRGBQuad;
  x: Integer;
begin

  bm := TBitmap.Create;
  try
    bm.SetSize(1024, 1024);
    bm.PixelFormat := pf32bit;
    for y := 0 to bm.Height - 1 do
    begin
      sl := bm.ScanLine[y];
      for x := 0 to bm.Width - 1 do
      begin
        sl.rgbBlue := 255 * x div bm.Width;
        sl.rgbRed := 255 * y div bm.Height;
        sl.rgbGreen := 255 * x div bm.Width;
        inc(sl);
      end;
    end;

    Canvas.Draw(0, 0, bm);
  finally
    bm.Free;
  end;

end;

如何在不先加载图像的情况下使用扫描线绘制？

How do I draw with scanlines without loading an image first?

delphi

tbitmap

delphi-xe