如何从实模式写入显存地址为0xb8000的屏幕？

Question

我创建了简单的代码来从硬盘驱动器加载第二个扇区，然后写入整个屏幕，带有红色背景的空格。问题是我总是得到 @ 符号而不是空格。这是代码：

org 0x7C00
bits 16

xor ax,ax
mov ds,ax
mov es,ax

mov bx,0x8000
cli
mov ss,bx
mov sp,ax
sti

cld
clc

xor ah,ah
int 0x13
mov bx,0x07E0
mov es,bx
xor bx,bx
mov ah,0x2 ;function
mov al,0x5 ;sectors to read
mov ch,0x0 ;track
mov cl,0x2 ;sector
mov dh,0x0 ;head
int 0x13
;jc error
;mov ah, [0x7E00]
;cmp ah,0x0
;je error
jmp error
cli
hlt
jmp 0x07E0:0x0000

error:
    xor bx,bx
    mov ax,0xb800
    mov es,ax
    mov al,0x40 ;colour
    mov ah,' ' ;character
    .red:
        cmp bx,0x0FA0
        je .end
        mov WORD [es:bx], ax
        inc bx
        jmp .red
    .end:
        cli
        hlt

times 0x1FE - ($ - $$) db 0x0
db 0x55
db 0xAA

根据此代码屏幕应该用空格填充，但事实并非如此。

Answer 1

写入显存时（从@0xb8000开始）屏幕上的每个单元格有2个字节。要显示的字符在第一个字节中，属性在第二个字节中。要将红色（颜色代码 0x40）space (0x20) 字符打印到屏幕上的第一个单元格，字节需要像这样放在内存中：

0xb800:0x0000 :  0x20         ; ASCII char for 0x20 is ' '
0xb800:0x0001 :  0x40         ; Red background, black foreground

在您的代码中，您似乎在尝试使用如下代码执行此操作：

mov al,0x40 ;colour
mov ah,' ' ;character
.red:
    cmp bx,0x0FA0
    je .end
    mov WORD [es:bx], ax
    inc bx
    jmp .red

不幸的是，因为 x86 体系结构是小尾数法，所以放入内存的值首先是最低有效字节，最后是最高有效字节（处理 16 位 WORD).您有包含 0x2040 的 AX 并将带有 mov WORD [es:bx], ax 的整个 WORD 移动到显存。例如，它会将这些字节写入第一个单元格：

0xb800:0x0000 :  0x40         ; ASCII char for 0x40 is `@'
0xb800:0x0001 :  0x20         ; Green background, black foreground

我相信这是绿色的 @ 但由于我要提到的第二个错误，它可能显示为红色。要解决此问题，您需要反转字符和属性在 AX 寄存器中的位置（交换 AH 和 中的值AL)。代码如下所示：

mov ah,0x40 ;colour is now in AH, not AL 
mov al,' '  ;character is now in AL, not AH
.red:
    cmp bx,0x0FA0
    je .end
    mov WORD [es:bx], ax
    inc bx
    jmp .red

第二个bug与遍历视频区域有关。因为每个单元格占用 2 个字节，所以您需要在每次迭代时将 BX 计数器递增 2。您的代码：

mov WORD [es:bx], ax
inc bx                 ; Only increments 1 byte where it should be 2 
jmp .red

修改代码BX加2:

mov WORD [es:bx], ax
add bx,2               ; Increment 2 since each cell is char/attribute pair 
jmp .red

您可以使用 STOSW instruction that takes the value in AX and copies it to ES:[DI]. You can prefix this instruction with REP 来简化代码，它将重复 CX 次（它会在每次迭代期间相应地更新 DI）。代码可能如下所示：

error:
    mov ax,0xb800 
    mov es,ax     ;Set video segment to 0xb800
    mov ax,0x4020 ;colour + space character(0x20)
    mov cx,2000   ;Number of cells to update 80*25=2000
    xor di,di     ;Video offset starts at 0 (upper left of screen)
    rep stosw     ;Store AX to CX # of words starting at ES:[DI]

您的代码已经在代码开头用 CLD 清除了方向标志，因此 REP 将增加 每次迭代期间 DI。如果方向标志设置为 STD，DI 将会递减。

如何从实模式写入显存地址为0xb8000的屏幕？

How to write to screen with video memory address 0xb8000 from real mode?

assembly

x86

nasm

bare-metal

real-mode