矩形碰撞 - 不需要的重叠。（处理中 IDE）

Question

所以我有这个简单的处理草图，其中块跟随鼠标。它有一个基本的碰撞功能，检测两个矩形之间的交点，然后将矩形 A 的位置设置为等于矩形 B 的位置减去矩形 A 的宽度（假设矩形 B 在 A 的前面）。不幸的是，这种方法是不够的，矩形之间有轻微的重叠。我真的希望矩形能够完美排列，就好像它们是一条矩形一样。有没有办法做到这一点？下面是我的可运行草图：

class Block {
  color c = color(random(255), random(255), random(255));
  float x = random(width);
  float speed = random(3, 6);
  void run() {
    float dir = mouseX - x;
    dir /= abs(dir);
    x += dir * speed;
    fill(c);
    rect(x, 300, 30, 60);
  }
  void collide() {
    for (Block other : blocks) {
      if (other != this) {
        if (x + 30 > other.x && x + 30 <= other.x + 15)
          x = other.x - 30;
        else if (x < other.x + 30 && x > other.x + 15)
          x = other.x + 30;
      }
    }
  }
}
Block[] blocks = new Block[6];
void setup() {
  size(600, 600);
  for (int i = 0; i < blocks.length; i++)
    blocks[i] = new Block();
}
void draw() {
  background(255);
  for (Block b : blocks) {
    b.run();
    b.collide();
  }
}
void mousePressed() {
  setup();
}

Answer 1

您好，我根据 http://ejohn.org/apps/processing.js/examples/topics/bouncybubbles.html

中的多对象碰撞示例更新了您的代码

想法是按以下顺序执行步骤：

根据物体的速度和方向更新每个物体的位置
检查碰撞并调整位置以适应新约束
显示对象

我为 Block 创建了一个新方法 display()，即在碰撞检测后更新位置后运行。矩形未显示在 run() 中，因为它们的位置不正确。在设置时调用的方法 overlap() 会在初始化草图时处理重叠的矩形。

希望对您有所帮助！

class Block {
  color c = color(random(255), random(255), random(255));
  float x = random(width);
  float speed = random(3, 6);
  void run() {
    float dir = mouseX - x;
    dir /= abs(dir);
    x += dir * speed;
  }
  void display() {
    fill(c);
    rect(x, 300, 30, 60);
  }
  void collide() {
    for (Block other : blocks) {
      if (other != this) {
        if (x + 30 > other.x && x + 30 <= other.x + 15) {
          x = other.x - 30;
        }
        else if (x < other.x + 30 && x > other.x + 15) {
          x = other.x + 30;
        }
      }
    }
  }
  void overlap() {
    for (Block other : blocks) {
      if (other != this) {
        if (x + 30 > other.x && x + 30 <= other.x + 30) {
          x = other.x - 30;
        }
      }
    }
  }
}
Block[] blocks = new Block[6];
void setup() {
  size(600, 600);
  for (int i = 0; i < blocks.length; i++) {
    blocks[i] = new Block();
  }
   for (Block b : blocks) {
     b.overlap();
   }
}
void draw() {
  background(255);
  for (Block b : blocks) {
   b.run();
   b.collide();
   b.display();
  }
}
void mousePressed() {
  setup();
}

PS 还为 1 行 if 语句添加了一些额外的大括号，即使没有必要也会使代码更 "safe"

矩形碰撞 - 不需要的重叠。（处理中 IDE）

Rectangle collision - Unwanted overlapping. (Processing IDE)

java

processing

collision-detection

collision

矩形碰撞 - 不需要的重叠。 （处理中 IDE）

Rectangle collision - Unwanted overlapping. (Processing IDE)

java

processing

collision-detection

collision

矩形碰撞 - 不需要的重叠。（处理中 IDE）