GLSL 中的矩阵平移被无限拉伸

Question

我使用 webgl 并修改着色器（vs.glsls 和 fs.glsl）以了解 GLSL 和图形编程。我有一个模型，我想缩放、旋转和平移。缩放和旋转效果很好，但是当我乘以平移矩阵时，结果很奇怪。我知道这是一个非常基本的问题，但我遗漏了一些东西，我需要找出来。我的模型在 y 轴上被无限拉伸。

白色区域应该是模特的眼睛：

这是我的顶点着色器代码：

mat4 rX = mat4 (
 1.0, 0.0, 0.0, 0.0,
 0.0, 0.0, -1.0, 0.0,
 0.0, 1.0, 0.0, 0.0,
 0.0, 0.0, 0.0, 1.0
 );

mat4 rZ = mat4 (
 0.0, 1.0, 0.0, 0.0,
 -1.0, 0.0, 0.0, 0.0,
 0.0, 0.0, 1.0, 0.0,
 0.0, 0.0, 0.0, 1.0
 );

mat4 eyeScale = mat4 (
 .50,0.0,0.0,0.0,
 0.0,.50,0.0,0.0,
 0.0,0.0,.50,0.0,
 0.0,0.0,0.0,1.0
 );
mat4 eyeTrans = mat4(
1.0,0.0,0.0,0.0,
0.0,1.0,0.0,4.0,
0.0,0.0,1.0,0.0,
0.0,0.0,0.0,1.0
);
 mat4 iR = eyeTrans*rZ*rX*eyeScale;
 gl_Position = projectionMatrix * modelViewMatrix  *iR* vec4(position, 1.0);
}

Answer 1

您在设置平移矩阵时交换了行和列

改为：

mat4 eyeTrans = mat4(
    1.0, 0.0, 0.0, 0.0,
    0.0, 1.0, 0.0, 0.0,
    0.0, 0.0, 1.0, 0.0,
    0.0, 4.0, 0.0, 1.0
);

一个 4*4 矩阵看起来像这样：

  c0  c1  c2  c3            c0  c1  c2  c3
[ Xx  Yx  Zx  Tx ]        [  0   4   8  12 ]     
[ Xy  Yy  Zy  Ty ]        [  1   5   9  13 ]     
[ Xz  Yz  Zz  Tz ]        [  2   6  10  14 ]     
[  0   0   0   1 ]        [  3   7  11  15 ]

在 GLSL 中，列的地址如下：

vec4 c0 = eyeTrans[0].xyzw;
vec4 c1 = eyeTrans[1].xyzw;
vec4 c2 = eyeTrans[2].xyzw;
vec4 c3 = eyeTrans[3].xyzw;

而一个 4*4 矩阵的内存图像是这样的：

[ Xx, Xy, Xz, 0, Yx, Yy, Yz, 0, Zx, Zy, Zz, 0, Tx, Ty, Tz, 1 ]

进一步了解：

GLSL 4×4 Matrix Fields

GLSL 中的矩阵平移被无限拉伸

Matrix Translation in GLSL is infinitely stretched

opengl-es

glsl

matrix

webgl

coordinate-transformation