为什么这些矩形有时会显示它们正在碰撞，而实际上它们并没有发生碰撞？

Question

当我运行代码时，它会生成 16 个具有随机大小、随机位置和随机颜色的矩形。如果它与另一个矩形发生碰撞，那么它应该变成白色。大多数时候它工作正常，但有时矩形在没有与任何东西碰撞时会变成白色。

主要

int boxCount = 16;
Box[] boxes = new Box[boxCount];

void setup(){
  size(500, 500);

  for(int i = 0; i < boxCount; i++){
    boxes[i] = new Box(random(50, width - 50), random(50, height - 50), random(20, 50), random(20, 50), color(random(0, 255), random(0, 255), random(0, 255)));
  }
}

void draw(){
  for(int i = 0; i < boxCount; i++){
    boxes[i].create();
    for(int x = 0; x < boxCount; x++){
      if(boxes[i] != boxes[x]){
        boxes[i].collide(boxes[x]);
      }
    }
  }
}

Class

class Box{
  float x;
  float y;
  float w;
  float h;
  color c;

  Box(float _x, float _y, float _w, float _h, color _c){
    x = _x;
    y = _y;
    w = _w;
    h = _h;
    c = _c;
  }

  void create(){
    fill(c);
    rect(x, y, w, h);
  }

  void collide(Box o){
    float right = x + (w / 2);
    float left = x - (w / 2);
    float top = y - (h / 2);
    float bottom = y + (h / 2);

    float oRight = o.x + (o.w / 2);
    float oLeft = o.x - (o.w / 2);
    float oTop = o.y - (o.h / 2);
    float oBottom = o.y + (o.h / 2);

    if(right > oLeft && left < oRight && bottom > oTop && top < oBottom){
      c = color(255, 255, 255);
    }
  }
}

Answer 1

rect 不会围绕中心点绘制矩形，默认情况下矩形绘制在左上角位置 (x, y)，大小为 (with, height).

您有 2 种可能性来解决问题：

要么改变碰撞检测方法：

class Box{

    // [...]

    void collide(Box o){    
        if(x < o.x+o.w  && o.x < x+w && y < o.y+o.h && o.y < y+h){
            c = color(255, 255, 255);
        }
    }
}

或设置CENTERrectMode()，这将导致矩形按照您的预期绘制：

class Box{

    // [...]

    void create(){
        fill(c);
        rectMode(CENTER);
        rect(x, y, w, h);
    }

    // [...]
}

为什么这些矩形有时会显示它们正在碰撞，而实际上它们并没有发生碰撞？

Why do these rectangles sometimes show that they are colliding even though they are not?

java

processing

collision-detection

rectangles