如何在glsl中绘制带边框的平滑圆圈？

Question

我想在 GLSL 中绘制一个平滑的圆，但边框宽度可变，颜色不同。潜在地，圆圈的内部可以是透明的。

我原来的非平滑着色器：

#version 330

layout(location=0) out vec4 frag_colour;

in vec4 color;

uniform float radius;
uniform vec2 position;
uniform vec4 borderColor;
uniform float borderThickness;

void main()
{
    float distanceX = abs(gl_FragCoord.x - position.x);
    float distanceY = abs(gl_FragCoord.y - position.y);

    if(sqrt(distanceX * distanceX + distanceY * distanceY) > radius)
        discard;
    else if(sqrt(distanceX * distanceX + distanceY * distanceY) <= radius &&
            sqrt(distanceX * distanceX + distanceY * distanceY) >= radius-borderThickness)
        frag_colour = borderColor;
    else
        frag_colour = color;
}

这可行，但不流畅。我可以画圆滑的圆圈：

#version 330

layout(location=0) out vec4 frag_colour;

in vec4 color;

uniform float radius;
uniform vec2 position;
uniform vec4 borderColor;
uniform float borderThickness;

void main()
{
    vec2 uv = gl_FragCoord.xy - position;

    float d = sqrt(dot(uv,uv));

    float t = 1.0 - smoothstep(radius-borderThickness,radius, d);

    frag_colour = vec4(color.rgb,color.a*t);
}

但我不知道如何在上面添加边框。

Answer 1

您必须计算半径和距离之间的差值的绝对值，并在 0.0 和 borderThickness 之间进行插值：

float t = 1.0 - smoothstep(0.0, borderThickness, abs(radius-d));

如果你想填充圆圈，那么你需要2个渐变。 1 用于内圆和边框之间的过渡，第二个用于轮廓上的 alpha 通道。 mix前者的颜色和后者设置的alpha通道：

float t1 = 1.0 - smoothstep(radius-borderThickness, radius, d);
float t2 = 1.0 - smoothstep(radius, radius+borderThickness, d);
frag_colour = vec4(mix(color.rgb, baseColor.rgb, t1), t2);

如何在glsl中绘制带边框的平滑圆圈？

How to draw a smooth circle with a border in glsl?

glsl

shader

fragment-shader

blending