glGetUniformLocation returns -1 对于 GLSL 中的结构数组

Question

我正在尝试对结构数组调用 glGetUniformLocation()。我读到我应该使用这种名称格式：“uniformName[index].element”，但方法总是 returns -1。我试图删除数组并仅使用该结构并且它有效所以我猜问题可能在那里。这是我的片段着色器中的结构和数组：


const int MAX_BLOCKS = 16;

struct sblock{

    vec4 color;
    float shineDamper;
    float reflectivity;
};

uniform sblock blocks[MAX_BLOCKS];

这是我的电话：

for(int i = 0; i < 16; i++) {
            location_block_color[i] = super.getUniformLocation("blocks["+i+"].color");
            location_block_reflectivity[i] = super.getUniformLocation("blocks["+i+"].reflectivity");
            location_block_shineDamper[i] = super.getUniformLocation("blocks["+i+"].shineDamper");
            System.out.println(location_block_color[i] + " " + location_block_reflectivity[i] + " " + location_block_shineDamper[i]); // prints -1 -1 -1 ...
        }

getUniformLocation 方法：

protected int getUniformLocation(String uniformName) {
        return GL20.glGetUniformLocation(programID, uniformName);
    }

这就是我创建 programID 的方式（在其他任何事情之前）：

vertexShaderID = loadShader(vertexFile, GL20.GL_VERTEX_SHADER);
        fragmentShaderID = loadShader(fragmentFile, GL20.GL_FRAGMENT_SHADER);
        programID = GL20.glCreateProgram();

我的问题是这里发生了什么，我做错了什么？感谢您的帮助。

编辑 1：

这是我的完整片段着色器：


#version 400 core

const int MAX_LIGHTS = 16;
const int MAX_BLOCKS = 16;

struct sblock{

    vec4 color;
    float shineDamper;
    float reflectivity;
};

uniform sblock blocks[MAX_BLOCKS];


in int block_id_out;
in vec3 unitNormal;
in vec3 lightVector[MAX_LIGHTS];
in vec3 directionalLightFinalColour;
in vec3 directionalLightReflected;

in vec3 toCameraVector;

in float visibility;

out vec4 outColor;


uniform float ambientLight;
uniform vec3 skyColor;

uniform vec3 lightColour[MAX_LIGHTS];
uniform vec3 attenuation[MAX_LIGHTS];
uniform int lightCount;
uniform vec3 directionalLightColour;
uniform vec3 directionalLightDirection;

vec3 calculateDiffuse(vec3 unitNormal, vec3 unitLightVector, vec3 lightColour, float attFactor){
    float nDotl = dot(unitNormal,unitLightVector);
    float brightness = max(nDotl,0);
    return (brightness * lightColour) / attFactor;
}


vec3 calculateSpecular(vec3 unitNormal, vec3 unitLightVector, vec3 unitToCameraVector, float shineDamper, float reflectivity, vec3 lightColour, float attFactor){
    vec3 reflectedLightDirection = reflect(-unitLightVector,unitNormal);
    float specularFactor = max(dot(reflectedLightDirection, unitToCameraVector),0.0);
    float dampedFactor = pow(specularFactor,shineDamper);
    return (dampedFactor * reflectivity * lightColour) / attFactor;
}

void main(void){

    vec3 totalDiffuse = vec3(0.0);
    vec3 totalSpecular = vec3(0.0);
        
    vec3 unitToCameraVector = normalize(toCameraVector);

    for(int i = 0; i < lightCount;i++){
        vec3 unitLightVector = normalize(lightVector[i]);
        float lightDistance = length(lightVector[i]);
        
        float attFactor = attenuation[i].x + attenuation[i].y*lightDistance + attenuation[i].z*lightDistance*lightDistance;
        
        totalSpecular += calculateSpecular(unitNormal, unitLightVector, unitToCameraVector, blocks[block_id_out].shineDamper, blocks[block_id_out].reflectivity, lightColour[i], attFactor);
        totalDiffuse += calculateDiffuse(unitNormal, unitLightVector, lightColour[i], attFactor);
    }
    
    totalDiffuse += directionalLightFinalColour;
    totalSpecular += pow(max(dot(directionalLightReflected,unitToCameraVector),0.0),blocks[block_id_out].shineDamper)*blocks[block_id_out].reflectivity*directionalLightColour;
    totalDiffuse = max(totalDiffuse,ambientLight);
    
    outColor = vec4(totalDiffuse,1.0) * blocks[block_id_out].color + vec4(totalSpecular,1.0);
    outColor = mix(vec4(skyColor,1.0),outColor,visibility);
}

编辑 2：

这是我的顶点着色器：


#version 400 core
const vec4 normals[] = vec4[6](vec4(1,0,0,0),vec4(0,1,0,0),vec4(0,0,1,0),vec4(-1,0,0,0),vec4(0,-1,0,0),vec4(0,0,-1,0));
const int MAX_LIGHTS = 16;

in vec3 position;
in int block_id;
in int normal;

out int block_id_out;
out vec3 unitNormal;
out vec3 lightVector[MAX_LIGHTS];
out vec3 directionalLightFinalColour;
out vec3 directionalLightReflected;
out vec3 toCameraVector;
out float visibility;

uniform mat4 transformationMatrix;
uniform mat4 projectionMatrix;
uniform mat4 viewMatrix;
uniform vec3 lightPosition[MAX_LIGHTS];
uniform vec3 directionalLight;
uniform vec3 directionalLightColor;

uniform int lightCount;

uniform float fogDensity;
uniform float fogGradient;

void main(void){

    vec4 worldPosition = transformationMatrix * vec4(position,1.0);
    vec4 positionRelativeToCam = viewMatrix * worldPosition;
    
    gl_Position = projectionMatrix * positionRelativeToCam;
    block_id_out = block_id;
    unitNormal = normalize((transformationMatrix * normals[normal]).xyz);
    
    for(int i = 0; i < lightCount;i++){
        lightVector[i] = lightPosition[i] - worldPosition.xyz;
    }
    directionalLightFinalColour = max(dot(unitNormal, directionalLight),0)*directionalLightColor;
    directionalLightReflected = reflect(-directionalLight,unitNormal);
    
    toCameraVector = (inverse(viewMatrix) * vec4(0.0,0.0,0.0,1.0)).xyz - worldPosition.xyz;
    
    visibility = clamp(exp(-pow(length(positionRelativeToCam.xyz)*fogDensity,fogGradient)),0.0,1.0);
}

Answer 1

来自（最近的）OpenGL Shading Language 4.60 Specification (HTML) - 4.3.9. Interface Blocks

A uniform or shader storage block array can only be indexed with a dynamically uniform integral expression, otherwise results are undefined.

block_id_out 是片段着色器输入（由顶点着色器输入设置）而不是 Dynamically uniform expression。因此 blocks[block_id_out] 未定义且无法保证 blocks[i] 成为活动程序资源。

我建议更改声明。不要创建一系列制服。创建单个 Uniform block:

const int MAX_BLOCKS = 16;

struct Block
{
    vec4 color;
    float shineDamper;
    float reflectivity;
};

layout(std140) uniform Blocks
{
    Block blocks[MAX_BLOCKS];
};

您必须创建一个 Uniform Buffer Object 以将数据绑定到统一块。

Answer 2

我认为@Rabbid76 的回答是正确的，但我找到了一个更令人满意的解决方法。我在顶点着色器中定义了 struct 和 uniform，然后将正确的颜色、shinedamper 和反射率值传递给片段着色器。这更有意义，因为我只想访问每个顶点的值，并且它们在片段着色器中是相同的，所以对每个三角形执行 3 次比对每个像素执行数百次要好。

glGetUniformLocation returns -1 对于 GLSL 中的结构数组

glGetUniformLocation returns -1 for an array of struct in GLSL

opengl

glsl

shader

lwjgl