HLSL 中的纹理采样器不进行插值

Question

我目前正在处理多纹理地形，但我遇到了 Sample function of Texture2DArray 的问题。

在我的示例中，我使用 Texture2DArray 来存储一组不同的地形纹理，例如草地、沙子、沥青等。我的每个顶点都存储一个纹理坐标（UV 坐标）和一个我想使用的纹理索引。因此，如果我的索引为 0，我将使用第一个纹理。如果索引为 1，我将使用第二个纹理，依此类推。只要我的索引是自然数（0、1、..），这就可以正常工作。但是，如果索引是实数（如 1.5f），它会失败。

为了查找问题，我将整个像素着色器缩减为：

Texture2DArray DiffuseTextures : register(t0);
Texture2DArray NormalTextures : register(t1);
Texture2DArray EmissiveTextures : register(t2);
Texture2DArray SpecularTextures : register(t3);
SamplerState Sampler : register(s0);

struct PS_IN
{
    float4 pos : SV_POSITION;
    float3 nor : NORMAL;
    float3 tan : TANGENT;
    float3 bin : BINORMAL;
    float4 col : COLOR;
    float4 TextureIndices : COLOR1;
    float4 tra : COLOR2;
    float2 TextureUV : TEXCOORD0;
};

float4 PS(PS_IN input) : SV_Target
{
    float4 texCol = DiffuseTextures.Sample(Sampler, float3(input.TextureUV, input.TextureIndices.r));

    return texCol;
}

下图显示了左侧示例场景的结果。如您所见，使用的纹理之间存在硬边界。没有插值形式。

为了检查我的纹理索引，我通过将纹理索引作为颜色返回来更改上面的像素着色器：

return float4(input.TextureIndices.r, input.TextureIndices.r, input.TextureIndices.r, 1.0f);

结果可以在图像的右侧看到。纹理索引是正确的，因为它们的范围在 [0, 1] 区间内，您可以清楚地看到区域边界处的插值。但是，我的采样纹理没有显示任何形式的插值。

由于我的像素着色器非常简单，我想知道是什么导致了这种行为？ DirextX 中是否有任何设置对此负责？

我使用 DirectX 11、像素着色器 ps_5_0（我还使用 ps_4_0 进行了测试）并且我使用 DDS 纹理（BC3 压缩）。

编辑

这是我正在使用的采样器：

SharpDX.Direct3D11.SamplerStateDescription samplerStateDescription = new SharpDX.Direct3D11.SamplerStateDescription()
{
    AddressU = SharpDX.Direct3D11.TextureAddressMode.Wrap,
    AddressV = SharpDX.Direct3D11.TextureAddressMode.Wrap,
    AddressW = SharpDX.Direct3D11.TextureAddressMode.Wrap,
    Filter = SharpDX.Direct3D11.Filter.MinMagMipLinear
};

SharpDX.Direct3D11.SamplerState samplerState = new SharpDX.Direct3D11.SamplerState(_device, samplerStateDescription);

_deviceContext.PixelShader.SetSampler(0, samplerState);

解决方案

我使用 catflier 提供的代码创建了一个函数来获取纹理颜色：

float4 GetTextureColor(Texture2DArray textureArray, float2 textureUV, float textureIndex)
{
    float tid = textureIndex;
    int id = (int)tid;
    float l = frac(tid);

    float4 texCol1 = textureArray.Sample(Sampler, float3(textureUV, id));
    float4 texCol2 = textureArray.Sample(Sampler, float3(textureUV, id + 1));

    return lerp(texCol1, texCol2, l);
}

这样，我可以通过简单的函数调用获得所有纹理类型（漫反射、镜面反射、自发光...）所需的纹理颜色：

float4 texCol = GetTextureColor(DiffuseTextures, input.TextureUV, input.TextureIndices.r);
float4 bumpMap = GetTextureColor(NormalTextures, input.TextureUV, input.TextureIndices.g);
float4 emiCol = GetTextureColor(EmissiveTextures, input.TextureUV, input.TextureIndices.b);
float4 speCol = GetTextureColor(SpecularTextures, input.TextureUV, input.TextureIndices.a);

结果如我所愿：:-)

Answer 1

纹理数组不跨切片采样，因此从技术上讲，这是预期的结果。

如果你想在切片之间进行插值（例如：1.5f 给你 "half" 的第二个纹理和 "half" 的第三个纹理），你可以改用 Texture3d，它允许这样做（但是将花费更多，因为它将执行三线性过滤）

否则，您可以这样执行采样：

float4 PS(PS_IN input) : SV_Target
{
    float tid = input.TextureIndices.r;
    int id = (int)tid; 
    float l = frac(tid); //lerp amount

    float4 texCol1 = DiffuseTextures.Sample(Sampler, float3(input.TextureUV,id));
    float4 texCol2 = DiffuseTextures.Sample(Sampler, float3(input.TextureUV,id+1));
return lerp(texCol1,texCol2, l);

}

请注意，此技术更加灵活，因为您还可以提供非相邻切片作为输入（例如，您可以在切片 2 和 23 之间插值），并最终通过将插值更改为一些其他功能。

HLSL 中的纹理采样器不进行插值

Texture sampler in HLSL does not interpolate

directx

textures

hlsl

directx-11

pixel-shader